/*-------------------------------------------------------------------*/
/*                                                                   */
/*  Program . . : SEC107T                                            */
/*  Description : Print SSL Trace Data - Run trace continuously      */
/*  Author  . . : Carsten Flensburg                                  */
/*                                                                   */
/*                                                                   */
/*                                                                   */
/*  Program function:  Continuously outputs trace records to the     */
/*                     trace output file, clears the trace table     */
/*                     and restarts the trace.                       */
/*                                                                   */
/*                     If run on a daily basis this program keeps    */
/*                     the trace table size down and ensures that    */
/*                     the trace output file is reflecting the       */
/*                     most recent SSL traffic on the system.        */
/*                                                                   */
/*                     The trace records are added to the trace      */
/*                     output file, that will be accumulating the    */
/*                     trace records and grow over time. Depending   */
/*                     on the volume of SSL traffic, be sure to      */
/*                     keep track of the disk space consumed by      */
/*                     the trace output file.                        */
/*                                                                   */
/*                     To format and query the SSL trace data,       */
/*                     use the Print SSL Trace Data (PRTSSLTRC)      */
/*                     command.                                      */
/*                                                                   */
/*                                                                   */
/*  Compile options:                                                 */
/*    CrtClPgm    Pgm( SEC107T )                                     */
/*                SrcFile( QCLSRC )                                  */
/*                SrcMbr( *PGM )                                     */
/*                                                                   */
/*-------------------------------------------------------------------*/
     Pgm

     MonMsg      CPF0000    *N        GoTo Error


     TrcInt      Set( *OFF )                          +
                 TrcTbl( 'SSL-1700x' )                +
                 Output( *OUTFILE )                   +
                 OutFile( QGPL/SSL1700X )             +
                 OutMbr( *FIRST *ADD )

     TrcInt      Set( *END )                          +
                 TrcTbl( 'SSL-1700x' )

     TrcInt      Set( *ON )                           +
                 TrcTbl( 'SSL-1700x' )                +
                 Size( 512 *MB )                      +
                 TrcType( *SCKSSL )                   +
                 SltTrcPnt(( 17000 17009 ))

     SndPgmMsg   Msg( 'SSL Trace Internal trace table SSL-1700x +
                       successfully processed.' )     +
                 MsgType( *COMP )


     Return

/*-- Error handling:  -----------------------------------------------*/
 Error:
     Call        QMHMOVPM    ( '    '                 +
                               '*DIAG'                +
                               x'00000001'            +
                               '*PGMBDY'              +
                               x'00000001'            +
                               x'0000000800000000'    +
                             )

     Call        QMHRSNEM    ( '    '                 +
                               x'0000000800000000'    +
                             )

 EndPgm:
     EndPgm
