/*-------------------------------------------------------------------*/
/*                                                                   */
/*  Program . . : SEC107M                                            */
/*  Description : Print SSL trace data - Create command              */
/*  Author  . . : Carsten Flensburg                                  */
/*                                                                   */
/*                                                                   */
/*                                                                   */
/*  Program function:  Compiles, creates and configures all the      */
/*                     command objects for the Print SSL Trace       */
/*                     Data command.                                 */
/*                                                                   */
/*                     This program expects a single parameter       */
/*                     specifying the library to contain the         */
/*                     command objects.                              */
/*                                                                   */
/*                     Object sources must exist in the respective   */
/*                     source type default source files in the       */
/*                     command object library.                       */
/*                                                                   */
/*                                                                   */
/*  NOTE: Prior to compiling this program please change the          */
/*        debug encryption key value (DbgEncKey) for the SEC107V     */
/*        module, if applicable.                                     */
/*                                                                   */
/*                                                                   */
/*  Compile options:                                                 */
/*    CrtClPgm    Pgm( SEC107M )                                     */
/*                SrcFile( QCLSRC )                                  */
/*                SrcMbr( *PGM )                                     */
/*                                                                   */
/*-------------------------------------------------------------------*/
     Pgm      &UtlLib

     Dcl      &UtlLib       *Char     10

     MonMsg      CPF0000    *N        GoTo Error


     CrtRpgMod   &UtlLib/SEC107                  +
                 SrcFile( &UtlLib/QRPGLESRC )    +
                 SrcMbr( *Module )               +
                 DbgView( *LIST )

     CrtPgm      &UtlLib/SEC107                  +
                 Module( &UtlLib/SEC107 )        +
                 ActGrp( *NEW )


     CrtRpgMod   &UtlLib/SEC107V                 +
                 SrcFile( &UtlLib/QRPGLESRC )    +
                 SrcMbr( *MODULE )               +
                 DbgView( *LIST )                +
                 DbgEncKey( secret )


     CrtPgm      &UtlLib/SEC107V                 +
                 Module( &UtlLib/SEC107V )       +
                 ActGrp( *NEW )


     CrtPnlGrp   &UtlLib/SEC107H                 +
                 SrcFile( &UtlLib/QPNLSRC )      +
                 SrcMbr( *PNLGRP )


     CrtCmd      Cmd( &UtlLib/PRTSSLTRC )                       +
                 Pgm( SEC107 )                                  +
                 SrcFile( &UtlLib/QCMDSRC )                     +
                 SrcMbr( SEC107X )                              +
                 VldCkr( SEC107V )                              +
                 MaxPos( 2 )                                    +
                 AlwLmtUsr( *NO )                               +
                 HlpPnlGrp( SEC107H )                           +
                 HlpId( *CMD )


     SndPgmMsg   Msg( 'Print SSL Trace Data command'      *Bcat +
                      'successfully created in library'   *Bcat +
                      &UtlLib                             *Tcat +
                      '.' )                                     +
                 MsgType( *COMP )


     Call        QMHMOVPM    ( '    '                 +
                               '*COMP'                +
                               x'00000001'            +
                               '*PGMBDY'              +
                               x'00000001'            +
                               x'0000000800000000'    +
                             )

     RmvMsg      Clear( *ALL )

     Return

/*-- Error handling:  -----------------------------------------------*/
 Error:
     Call        QMHMOVPM    ( '    '                 +
                               '*DIAG'                +
                               x'00000001'            +
                               '*PGMBDY'              +
                               x'00000001'            +
                               x'0000000800000000'    +
                             )

     Call        QMHRSNEM    ( '    '                 +
                               x'0000000800000000'    +
                             )

 EndPgm:
     EndPgm
