     **
     **  Program . . : SEC106
     **  Description : Retrieve Receiver Range - CPP
     **  Author  . . : Carsten Flensburg
     **
     **
     **
     **
     **  Compile options:
     **
     **    CrtRpgMod Module( CBX126 )  DbgView( *LIST )
     **
     **    CrtPgm    Pgm( CBX126 )
     **              Module( CBX126 )
     **              ActGrp( *NEW )
     **
     **
     **-- Header specifications:  --------------------------------------------**
     H Option( *SrcStmt )

     **-- Api error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPro                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0 Inz
     D  MsgId                         7a
     D                                1a
     D  MsgDta                      128a
     **-- Global variables:
     D Idx             s             10u 0
     D ApiRcvSiz       s             10u 0
     D BegDts          s               z
     D EndDts          s               z
     D AtcDts          s               z
     D DtcDts          s               z
     **
     D BegRcvNam       s             10a
     D BegRcvLib       s             10a
     D BegSeqNbr       s             20s 0
     D EndRcvNam       s             10a
     D EndRcvLib       s             10a
     D EndSeqNbr       s             20s 0
     **-- Global constants:
     D NULL            c                   ''
     D OFS_MSGDTA      c                   16
     D CYMD_HIVAL      c                   '9991231'

     **-- Journal information:
     D RJRN0100        Ds                  Based( pJrnInf )  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  OfsKeyInf                    10i 0
     D  JrnNam                       10a
     D  JrnLib                       10a
     D  ASP                          10i 0
     D  MsgQnam                      10a
     D  MsgQlib                      10a
     D  MngRcvOpt                     1a
     D  DltRcvOpt                     1a
     D  RsoRit                        1a
     D  RsoMfl                        1a
     D  RsoMo1                        1a
     D  RsoMo2                        1a
     D  Rsv1                          3a
     D  JrnTyp                        1a
     D  RmtJrnTyp                     1a
     D  JrnStt                        1a
     D  JrnDlvMod                     1a
     D  LocJrnNam                    10a
     D  LocJrnLib                    10a
     D  LocJrnSys                     8a
     D  SrcJrnNam                    10a
     D  SrcJrnLib                    10a
     D  SrcJrnSys                     8a
     D  RdrRcvLib                    10a
     D  JrnTxt                       50a
     D  MinEntDtaAr                   1a
     D  MinEntFiles                   1a
     D  Rsv2                          9a
     D  NbrAtcRcv                    10i 0
     D  AtcRcvNam                    10a
     D  AtcRcvLib                    10a
     D  AtcLocSys                     8a
     D  AtcSrcSys                     8a
     D  AtcRcvNamDu                  10a
     D  AtcRcvLibDu                  10a
     D  Rsv3                        192a
     D  NbrKey                       10i 0
     **
     D JrnKey          Ds                  Based( pJrnKey )  Qualified
     D  Key                          10i 0
     D  OfsKeyInf                    10i 0
     D  KeyHdrSecLn                  10i 0
     D  NbrEnt                       10i 0
     D  KeyInfEntLn                  10i 0
     **
     D JrnKeyHdr1      Ds                  Based( pKeyHdr1 )  Qualified
     D  RcvNbrTot                    10i 0
     D  RcvSizTot                    10i 0
     D  RcvSizMtp                    10i 0
     D  Rsv                           8a
     **
     D JrnKeyEnt1      Ds                  Based( pKeyEnt1 )  Qualified
     D  RcvNam_q                     20a
     D   RcvNam                      10a   Overlay( RcvNam_q:  1 )
     D   RcvLib                      10a   Overlay( RcvNam_q: 11 )
     D  RcvNbr                        5a
     D  RcvAtcDts                    13a
     D  RcvSts                        1a
     D  RcvSavDts                    13a
     D  LocJrnSys                     8a
     D  SrcJrnSys                     8a
     D  RcvSiz                       10i 0
     D  Rsv                          56a
     **-- Journal information specification:
     D JrnInfRtv       Ds                  Qualified
     D  NbrVarRcd                    10i 0 Inz( 1 )
     D  VarRcdLen                    10i 0 Inz( 12 )
     D  Key                          10i 0 Inz( 1 )
     D  DtaLen                       10i 0 Inz( 0 )
     **-- Receiver information:
     D RRCV0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  RcvNam                       10a
     D  RcvLib                       10a
     D  JrnNam                       10a
     D  JrnLib                       10a
     D  Thh                          10i 0
     D  Siz                          10i 0
     D  ASP                          10i 0
     D  NbrJrnEnt                    10i 0
     D  MaxEspDtaLn                  10i 0
     D  MaxNulInd                    10i 0
     D  FstSeqNbr                    10i 0
     D  MinEntDtaAr                   1a
     D  MinEntFiles                   1a
     D  Rsv1                          2a
     D  LstSeqNbr                    10i 0
     D  Rsv2                         10i 0
     D  Status                        1a
     D  MinFxlVal                     1a
     D  RcvMaxOpt                     1a
     D  Rsv3                          4a
     D  AtcDts                       13a
     D   AtcDat                       7a   Overlay( AtcDts: 1 )
     D   AtcTim                       6a   Overlay( AtcDts: *Next )
     D  DtcDts                       13a
     D   DtcDat                       7a   Overlay( DtcDts: 1 )
     D   DtcTim                       6a   Overlay( DtcDts: *Next )
     D  SavDts                       13a
     D   SavDat                       7a   Overlay( SavDts: 1 )
     D   SavTim                       6a   Overlay( SavDts: *Next )
     D  Txt                          50a
     D  PndTrn                        1a
     D  RmtJrnTyp                     1a
     D  LocJrnNam                    10a
     D  LocJrnLib                    10a
     D  LocJrnSys                     8a
     D  LocRcvLib                    10a
     D  SrcJrnNam                    10a
     D  SrcJrnLib                    10a
     D  SrcJrnSys                     8a
     D  SrcRcvLib                    10a
     D  RdcRcvLib                    10a
     D  DuaRcvNam                    10a
     D  DuaRcvLib                    10a
     D  PrvRcvNam                    10a
     D  PrvRcvLib                    10a
     D  PrvRcvNamDu                  10a
     D  PrvRcvLibDu                  10a
     D  NxtRcvNam                    10a
     D  NxtRcvLib                    10a
     D  NxtRcvNamDu                  10a
     D  NxtRcvLibDu                  10a
     D  NbrJrnEntL                   20s 0
     D  MaxEspDtlL                   20s 0
     D  FstSeqNbrL                   20s 0
     D  LstSeqNbrL                   20s 0
     D  AspDevNam                    10a
     D  LocJrnAspGn                  10a
     D  SrcJrnAspGn                  10a
     D  FldJob                        1a
     D  FldUsr                        1a
     D  FldPgm                        1a
     D  FldPgmLib                     1a
     D  FldSysSeq                     1a
     D  FldRmtAdr                     1a
     D  FldThd                        1a
     D  FldLuw                        1a
     D  FldXid                        1a
     D  Rsv4                         21a

     **-- Retrieve journal entry selection records:
     D JrnEntRtv       Ds                  Qualified
     D  NbrVarRcd                    10i 0
     **-- RCVRNG - *CURRENT, *CURCHAIN
     D JrnVarR01       Ds                  Qualified
     D  RcdLen                       10i 0 Inz( %Size( JrnVarR01 ))
     D  Key                          10i 0 Inz( 1 )
     D  DtaLen                       10i 0 Inz( %Size( JrnVarR01.Data ))
     D  Data                         40a   Inz( '*CURCHAIN' )
     D   RcvStr_q                    20a   Overlay( Data: 1 )
     D    RcvStr                     10a   Overlay( Data: 1 )
     D    LibStr                     10a   Overlay( Data: 11 )
     D   RcvEnd_q                    20a   Overlay( Data: 21 )
     D    RcvEnd                     10a   Overlay( Data: 21 )
     D    LibEnd                     10a   Overlay( Data: 31 )
     **-- FROMENT - *FIRST
     D JrnVarR02       Ds                  Qualified
     D  RcdLen                       10i 0 Inz( %Size( JrnVarR02 ))
     D  Key                          10i 0 Inz( 2 )
     D  DtaLen                       10i 0 Inz( %Size( JrnVarR02.Data ))
     D  Data                         20a   Inz( '*FIRST' )
     D  SeqNbr                       20s 0 Overlay( Data )
     **-- FROMTIME
     D JrnVarR03       Ds                  Qualified
     D  RcdLen                       10i 0 Inz( %Size( JrnVarR03 ))
     D  Key                          10i 0 Inz( 3 )
     D  DtaLen                       10i 0 Inz( %Size( JrnVarR03.Data ))
     D  Data                         26a
     **-- NBRENT
     D JrnVarR06       Ds                  Qualified
     D  RcdLen                       10i 0 Inz( %Size( JrnVarR06 ))
     D  Key                          10i 0 Inz( 6 )
     D  DtaLen                       10i 0 Inz( %Size( JrnVarR06.Data ))
     D  Data                         10i 0 Inz( 1 )
     **-- Retrieve journal entry data:
     D RJNE0200        Ds         65535    Qualified  Align
     D  JrnHdr
     D   BytRtn                      10i 0 Overlay( JrnHdr )
     D   OfsHdrJrnE                  10i 0 Overlay( JrnHdr: *Next )
     D   NbrEntRtv                   10i 0 Overlay( JrnHdr: *Next )
     D   ConInd                       1a   Overlay( JrnHdr: *Next )
     D   ConRcvStr                   10a   Overlay( JrnHdr: *Next )
     D   ConLibStr                   10a   Overlay( JrnHdr: *Next )
     D   ConSeqNbr                   20s 0 Overlay( JrnHdr: *Next )
     D                               11a   Overlay( JrnHdr: *Next )
     **-- Entry header:
     D EntHdr          Ds                  Qualified  Based( pEntHdr )
     D  OfsHdrJrnE                   10u 0
     D  OfsNulValI                   10u 0
     D  OfsEntDta                    10u 0
     D  OfsTrnId                     10u 0
     D  OfsLglUoW                    10u 0
     D  OfsRcvInf                    10u 0
     D  SeqNbr                       20u 0
     D  TimStp                       20u 0
     D  TimStpC                       8a   Overlay( TimStp )
     D  ThrId                        20u 0
     D  SysSeqNbr                    20u 0
     D  CntRrn                       20u 0
     D  CmtCclId                     20u 0
     D  PtrHdl                       10u 0
     D  RmtPort                       5u 0
     D  ArmNbr                        5u 0
     D  PgmLibAsp                     5u 0
     D  RmtAddr                      16a
     D  RmtAddr_i                    10u 0 Overlay( RmtAddr: 1 )
     D  JrnCde                        1a
     D  EntTyp                        2a
     D  JobNam_q                     26a
     D   JobNam                      10a   Overlay( JobNam_q )
     D   JobUsr                      10a   Overlay( JobNam_q: *Next )
     D   JobNbr                       6a   Overlay( JobNam_q: *Next )
     D  PgmNam                       10a
     D  PgmLib                       10a
     D  PgmLibAspDev                 10a
     D  Object                       30a
     D  UsrPrf                       10a
     D  JrnId                        10a
     D  AdrFam                        1a
     D  SysNam                        8a
     D  IndFlg                        1a
     D  ObjNamInd                     1a
     D  BitFld                        1a
     D  Rsv                           9a
     **-- Receiver information:
     D RcvInf          Ds                  Qualified  Based( pRcvInf )
     D  RcvNam_q                     20a
     D   RcvNam                      10a   Overlay( RcvNam_q: 1 )
     D   RcvLib                      10a   Overlay( RcvNam_q: *Next )
     D  RcvLibAspDev                 10a
     D  RcvLibAspNbr                  5i 0

     **-- Retrieve journal information:
     D RtvJrnInf       Pr                  ExtProc( 'QjoRetrieveJournal-
     D                                     Information' )
     D  RcvVar                    65535a         Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  JrnNam_q                     20a   Const
     D  FmtNam                        8a   Const
     D  InfRtv                    65535a   Const Options( *VarSize )
     D  Error                     32767a         Options( *VarSize: *Omit )
     **-- Retrieve journal receiver information:
     D RtvRcvInf       Pr                  ExtProc( 'QjoRtvJrnReceiver-
     D                                     Information' )
     D  RcvVar                    65535a         Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  RcvNam_q                     20a   Const
     D  FmtNam                        8a   Const
     D  Error                     32767a         Options( *VarSize: *Omit )
     **-- Retrieve journal entries:
     D RtvJrnE         Pr                  ExtProc( 'QjoRetrieveJournalEntries')
     D  RcvVar                    65535a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  JrnNam_q                     20a   Const
     D  RcvInfFmt                     8a   Const
     D  SltInf                    32767a   Const  Options( *Omit: *VarSize )
     D  Error                     32767a          Options( *Omit: *VarSize )
     **-- Delete pointer handle:
     D DltPtrHdl       Pr                  ExtProc( 'QjoDeletePointerHandle' )
     D  PtrHdl                       10u 0 Const
     D  Error                     32767a          Options( *Omit: *VarSize )
     **-- Register termination exit:
     D CeeRtx          Pr                    ExtProc( 'CEERTX' )
     D  procedure                      *     ProcPtr   Const
     D  token                          *     Options( *Omit )
     D  fb                           12a     Options( *Omit )
     **-- Unregister termination exit:
     D CeeUtx          Pr                    ExtProc( 'CEEUTX' )
     D  procedure                      *     ProcPtr   Const
     D  fb                           12a     Options( *Omit )
     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFil_q                     20a   Const
     D  MsgDta                      128a   Const
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                     32767a          Options( *VarSize )

     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **-- Get entry number from timestamp:
     D GetEntNbr       Pr            20s 0
     D  PxJrnNam_q                   20a   Const
     D  PxRcvNam_q                   20a   Const
     D  PxTimStp                       z   Const
     **-- Terminate program:
     D TrmPgm          Pr
     D  pPtr                           *

     **-- Entry parameters:
     D TimStp          Ds                  Template
     D  NbrElm                        5i 0
     D  Date                          7a
     D  Time                          6a
     **
     D SEC106          Pr
     D  PxJrnNam_q                   20a
     D  PxDtsBeg                           LikeDs( TimStp )
     D  PxDtsEnd                           LikeDs( TimStp )
     D  PxBegRcvNam                  10a
     D  PxBegRcvLib                  10a
     D  PxBegSeqNbr                  20a
     D  PxEndRcvNam                  10a
     D  PxEndRcvLib                  10a
     D  PxEndSeqNbr                  20a
     **
     D SEC106          Pi
     D  PxJrnNam_q                   20a
     D  PxDtsBeg                           LikeDs( TimStp )
     D  PxDtsEnd                           LikeDs( TimStp )
     D  PxBegRcvNam                  10a
     D  PxBegRcvLib                  10a
     D  PxBegSeqNbr                  20a
     D  PxEndRcvNam                  10a
     D  PxEndRcvLib                  10a
     D  PxEndSeqNbr                  20a

      /Free

        ExSr  InzParms;

        ApiRcvSiz = 65535;
        pJrnInf   = %Alloc( ApiRcvSiz );
        RJRN0100.BytAvl = *Zero;

        DoU  RJRN0100.BytAvl <= ApiRcvSiz     Or
             ERRC0100.BytAvl  > *Zero;

          If  RJRN0100.BytAvl > ApiRcvSiz;
            ApiRcvSiz = RJRN0100.BytAvl;
            pJrnInf   = %ReAlloc( pJrnInf: ApiRcvSiz );
          EndIf;

          RtvJrnInf( RJRN0100
                   : ApiRcvSiz
                   : PxJrnNam_q
                   : 'RJRN0100'
                   : JrnInfRtv
                   : ERRC0100
                   );
        EndDo;

        CeeRtx( %Paddr( TrmPgm ): pJrnInf: *Omit );

        If  ERRC0100.BytAvl > *Zero;
          ExSr  EscApiErr;
        Else;

          ExSr  PrcKeyEnt;
        EndIf;

        CeeUtx( %Paddr( TrmPgm ): *Omit );

        TrmPgm( pJrnInf );

        If  %Addr( PxBegRcvNam ) <> *Null;
          PxBegRcvNam = BegRcvNam;
        EndIf;

        If  %Addr( PxBegRcvLib ) <> *Null;
          PxBegRcvLib = BegRcvLib;
        EndIf;

        If  %Addr( PxBegSeqNbr ) <> *Null;
          PxBegSeqNbr = %Char( BegSeqNbr );
        EndIf;

        If  %Addr( PxEndRcvNam ) <> *Null;
          PxEndRcvNam = EndRcvNam;
        EndIf;

        If  %Addr( PxEndRcvLib ) <> *Null;
          PxEndRcvLib = EndRcvLib;
        EndIf;

        If  %Addr( PxEndSeqNbr ) <> *Null;
          PxEndSeqNbr = %Char( EndSeqNbr );
        EndIf;

        Return;


        BegSr PrcKeyEnt;

          pJrnKey  = pJrnInf  + RJRN0100.OfsKeyInf + %Size( RJRN0100.NbrKey );

          pKeyHdr1 = pJrnKey  + JrnKey.OfsKeyInf;
          pKeyEnt1 = pKeyHdr1 + %Size( JrnKeyHdr1 );

          For  Idx = 1  to JrnKey.NbrEnt;

            RtvRcvInf( RRCV0100
                     : %Size( RRCV0100 )
                     : JrnKeyEnt1.RcvNam_q
                     : 'RRCV0100'
                     : ERRC0100
                     );

            If  ERRC0100.BytAvl = *Zero;
              ExSr  PrcLstEnt;
            EndIf;

            If  Idx < JrnKey.NbrEnt;
              Eval pKeyEnt1 = pKeyEnt1 + JrnKey.KeyInfEntLn;
            EndIf;
          EndFor;

        EndSr;

        BegSr  InzParms;

          If  PxDtsBeg.NbrElm = 1;
            BegDts = *LoVal;

          Else;
            If  PxDtsBeg.Date = '0010000';
              PxDtsBeg.Date   = %Char( %Date(): *CYMD0 );
            EndIf;

            If  PxDtsBeg.Time = '000001';
              PxDtsBeg.Time   = %Char( %Time(): *HMS0 );
            EndIf;

            BegDts = %Date( PxDtsBeg.Date: *CYMD0 ) +
                     %Time( PxDtsBeg.Time: *HMS0 );
          EndIf;

          If  PxDtsEnd.NbrElm = 1;
            EndDts = *HiVal;

          Else;
            If  PxDtsEnd.Date = '0010000';
              PxDtsEnd.Date   = %Char( %Date(): *CYMD0 );
            EndIf;

            If  PxDtsEnd.Time = '000001';
              PxDtsEnd.Time   = %Char( %Time(): *HMS0 );
            EndIf;

            EndDts = %Date( PxDtsEnd.Date: *CYMD0 ) +
                     %Time( PxDtsEnd.Time: *HMS0 );

            If  EndDts > %Timestamp();
              EndDts = %Timestamp();
            EndIf;
          EndIf;

          If  EndDts < BegDts;
            SndEscMsg( 'CPF7054': 'QCPFMSG': NULL );
          EndIf;

        EndSr;

        BegSr  PrcLstEnt;

          If  RRCV0100.DtcDat = *Zeros;
            RRCV0100.DtcDat = CYMD_HIVAL;
          EndIf;

          AtcDts = %Date( RRCV0100.AtcDat: *CYMD0 ) +
                   %Time( RRCV0100.AtcTim: *HMS0 );

          DtcDts = %Date( RRCV0100.DtcDat: *CYMD0 ) +
                   %Time( RRCV0100.DtcTim: *HMS0 );

          Select;
          When  BegDts  = *Loval  And  Idx = 1;
            BegSeqNbr = RRCV0100.FstSeqNbrL;
            BegRcvNam = JrnKeyEnt1.RcvNam;
            BegRcvLib = JrnKeyEnt1.RcvLib;

          When  EndDts  = *Hival  And  Idx = JrnKey.NbrEnt;
            EndSeqNbr = RRCV0100.LstSeqNbrL;
            EndRcvNam = JrnKeyEnt1.RcvNam;
            EndRcvLib = JrnKeyEnt1.RcvLib;

          Other;
            If  BegDts >= AtcDts  And  BegDts < DtcDts;
              BegSeqNbr = GetEntNbr( PxJrnNam_q: JrnKeyEnt1.RcvNam_q: BegDts );
              BegRcvNam = JrnKeyEnt1.RcvNam;
              BegRcvLib = JrnKeyEnt1.RcvLib;
            EndIf;

            If  EndDts >= AtcDts  And  EndDts < DtcDts;
              EndSeqNbr = GetEntNbr( PxJrnNam_q: JrnKeyEnt1.RcvNam_q: EndDts );
              EndRcvNam = JrnKeyEnt1.RcvNam;
              EndRcvLib = JrnKeyEnt1.RcvLib;
            EndIf;
          EndSl;

        EndSr;

        BegSr  EscApiErr;

          If  ERRC0100.BytAvl < OFS_MSGDTA;
            ERRC0100.BytAvl = OFS_MSGDTA;
          EndIf;

          SndEscMsg( ERRC0100.MsgId
                   : 'QCPFMSG'
                   : %Subst( ERRC0100.MsgDta: 1: ERRC0100.BytAvl - OFS_MSGDTA )
                   );

        EndSr;

      /End-Free

     **-- Send escape message:
     P SndEscMsg       B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : PxMsgF + '*LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
     **-- Get entry number from timestamp:
     P GetEntNbr       B
     D                 Pi            20s 0
     D  PxJrnNam_q                   20a   Const
     D  PxRcvNam_q                   20a   Const
     D  PxTimStp                       z   Const
     **
     D Idx             s             10i 0

      /Free

        JrnVarR01.RcvStr_q = PxRcvNam_q;
        JrnVarR01.RcvEnd_q = PxRcvNam_q;

        JrnVarR03.Data = %Char( PxTimStp );

        JrnEntRtv.NbrVarRcd = 3;

        RtvJrnE( RJNE0200
               : %Size( RJNE0200 )
               : PxJrnNam_q
               : 'RJNE0200'
               : JrnEntRtv  +
                 JrnVarR01  +
                 JrnVarR03  +
                 JrnVarR06
               : ERRC0100
               );

        If  ERRC0100.BytAvl = *Zero;

          If  RJNE0200.NbrEntRtv > *Zero;

            pEntHdr = %Addr( RJNE0200 ) + RJNE0200.OfsHdrJrnE;

            For  Idx = 1  to  RJNE0200.NbrEntRtv;

              If  EntHdr.OfsRcvInf > *Zero;
                pRcvInf = pEntHdr + EntHdr.OfsRcvInf;
              EndIf;

              If  EntHdr.PtrHdl > *Zero;
                CallP(e)  DltPtrHdl( EntHdr.PtrHdl: *Omit );
              EndIf;

              Return  EntHdr.SeqNbr;

              If  Idx < RJNE0200.NbrEntRtv;
                pEntHdr += EntHdr.OfsHdrJrnE;
              EndIf;
            EndFor;
          EndIf;
        EndIf;

        Return   0;

      /End-Free

     P GetEntNbr       E
     **-- Terminate program:
     P TrmPgm          B
     D                 Pi
     D  pPtr                           *

      /Free

        DeAlloc  pPtr;

        *InLr = *On;

        Return;

      /End-Free

     P TrmPgm          E
