     **
     **  Program . . :  SEC105
     **  Description :  Work with User Auditing - CPP
     **  Author  . . :  Carsten Flensburg
     **
     **
     **
     **  Programmer's note:
     **
     **   The prerequisite SQLCLI_H copy member is available here:
     **     http://www.pentontech.com/IBMContent/Documents/article/56657_600_CliClob.zip
     **
     **
     **  Compile options:
     **    CrtRpgMod   Module( SEC105 )
     **                DbgView( *LIST )
     **
     **    CrtPgm      Pgm( SEC105 )
     **                Module( SEC105 )
     **                ActGrp( *NEW )
     **
     **
     **-- Header specifications:  --------------------------------------------**
     H Option( *SrcStmt )

      /copy SQLCLI_H

     **-- System information:
     D PgmSts         SDs                  Qualified
     D  PgmNam           *Proc
     D  CurJob                       10a   Overlay( PgmSts: 244 )
     D  UsrPrf                       10a   Overlay( PgmSts: 254 )
     D  JobNbr                        6a   Overlay( PgmSts: 264 )
     D  CurUsr                       10a   Overlay( PgmSts: 358 )
     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     D  MsgId                         7a
     D                                1a
     D  MsgDta                      128a

     **-- Global constants:
     D OFS_MSGDTA      c                   16
     D JOB_CCSID       c                   0
     D TYP_INTER       c                   'I'
     D MAX_AUD_VAL     c                   31
     D ADP_PRV_INVLVL  c                   1
     D NULL            c                   ''
     **
     D FMT_LVLID       c                   '51FBCE45030FA'
     D SQL_IGN_INT     c                   0
     **-- UIM constants:
     D PNLGRP_Q        c                   'SEC105P   *LIBL     '
     D PNLGRP          c                   'SEC105P   '
     D SCP_AUT_RCL     c                   -1
     D RDS_OPT_INZ     c                   'N'
     D PRM_IFC_0       c                   0
     D CLO_NORM        c                   'M'
     D FNC_EXIT        c                   -4
     D FNC_CNL         c                   -8
     D KEY_F05         c                   5
     D KEY_F17         c                   17
     D KEY_F18         c                   18
     D RTN_ENTER       c                   500
     D HLP_WDW         c                   'N'
     D POS_TOP         c                   'TOP'
     D POS_BOT         c                   'BOT'
     D LIST_COMP       c                   'ALL'
     D LIST_SAME       c                   'SAME'
     D EXIT_SAME       c                   '*SAME'
     D TRIM_SAME       c                   'S'
     **
     D APP_PRTF        c                   'QPRINT    *LIBL'
     D ODP_SHR         c                   'N'
     D SPLF_NAM        c                   'PWRKUSRAUD'
     D SPLF_USRDTA     c                   'WRKUSRAUD'
     D EJECT_NO        c                   'N'

     **-- Global variables:
     D Idx             s             10i 0
     D SysDts          s               z
     D SysName         s              8a
     D WrkUsr          s             10a
     D AutFlg          s              1a
     D SpcAutLst       s             10a   Dim( 8 )
     D CrtOutFil       s               n
     **
     D rc              s                   Like( SQLRETURN )
     D env             s                   Like( SQLHENV )
     D conn            s                   Like( SQLHDBC )
     D stmt            s                   Like( SQLHSTMT )
     **
     D SQLStmt         s           4096a   Varying
     D SQLTable        s             21a   Varying

     **-- SQL value lengths - taken at runtime:
     D lenParm1        s             10i 0 Inz( %Size( SQLValue.SysNam ))
     D lenParm2        s             10i 0 Inz( %Size( SQLValue.SysDts ))
     D lenParm3        s             10i 0 Inz( %Size( SQLValue.UsrPrf ))
     D lenParm4        s             10i 0 Inz( %Size( SQLValue.UsrCls ))
     D lenParm5        s             10i 0 Inz( %Size( SQLValue.GrpPrf ))
     D lenParm6        s             10i 0 Inz( %Size( SQLValue.ObjAudVal ))
     D lenParm7        s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm8        s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm9        s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm10       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm11       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm12       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm13       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm14       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm15       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm16       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm17       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm18       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm19       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm20       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm21       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm22       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm23       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm24       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm25       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm26       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm27       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm28       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm29       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm30       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm31       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm32       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm33       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm34       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm35       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm36       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     D lenParm37       s             10i 0 Inz( %Size( SQLValue.AudFlg ))
     **-- SQL insert values:
     D SQLValue        Ds                  Qualified
     D  SysNam                        8a
     D  SysDts                         z
     D  UsrPrf                       10a
     D  UsrCls                       10a
     D  GrpPrf                       10a
     D  ObjAudVal                    10a
     D  UsrAudVal                          LikeDs( AudLvl )
     D  AudFlg                        1a   Overlay( UsrAudVal )

     **-- Audit level:
     D AudLvl          Ds                  Qualified
     D  Cmd                           1a
     D  Create                        1a
     D  Delete                        1a
     D  JobDta                        1a
     D  ObjMgt                        1a
     D  OfcSrv                        1a
     D  PgmAdp                        1a
     D  SavRst                        1a
     D  Security                      1a
     D  Service                       1a
     D  SplfDta                       1a
     D  SysMgt                        1a
     D  Optical                       1a
     D  AutFail                       1a
     D  JobBas                        1a
     D  JobChgUsr                     1a
     D  NetBas                        1a
     D  NetClu                        1a
     D  NetCmn                        1a
     D  NetFail                       1a
     D  NetSck                        1a
     D  PgmFail                       1a
     D  PrtDta                        1a
     D  SecCfg                        1a
     D  SecDirSrv                     1a
     D  SecIpc                        1a
     D  SecNas                        1a
     D  SecRun                        1a
     D  SecSckD                       1a
     D  SecVfy                        1a
     D  SecVldL                       1a
     D  AudFlg                        1a   Dim( MAX_AUD_VAL )  Overlay( AudLvl )
     **-- Reference audit level:
     D RefAudLvl       Ds                  LikeDs( AudLvl )

     **-- UIM variables:
     D UIM             Ds                  Qualified
     D  AppHdl                        8a
     D  LstHdl                        4a
     D  EntHdl                        4a
     D  FncRqs                       10i 0
     D  EntLocOpt                     4a
     D  LstPos                        4a
     **-- List attributes structure:
     D LstAtr          Ds                  Qualified
     D  LstCon                        4a
     D  ExtPgmVar                    10a
     D  DspPos                        4a
     D  AlwTrim                       1a

     **-- UIM Panel header record:
     D HdrRcd          Ds                  Qualified
     D  SysDat                        7a
     D  SysTim                        6a
     D  TimZon                       10a
     D  WrkUsr                       10a
     D  PosUsr                       10a
     **-- UIM List entry:
     D LstEnt          Ds                  Qualified
     D  Option                        5i 0
     D  UsrPrf                       10a
     D  UsrCls                       10a
     D  GrpPrf                       10a
     D  ObjAudVal                    10a
     D  UsrAudVal                          LikeDs( AudLvl )
     **
     D LstEntPos       Ds                  LikeDs( LstEnt )

     **-- List API parameters:
     D LstApi          Ds                  Qualified  Inz
     D  RtnRcdNbr                    10i 0
     D  GrpNam                       10a
     D  SltCri                       10a
     D  UsrPrf                       10a
     **-- List information:
     D LstInf          Ds                  Qualified
     D  RcdNbrTot                    10i 0
     D  RcdNbrRtn                    10i 0
     D  Handle                        4a
     D  RcdLen                       10i 0
     D  InfSts                        1a
     D  Dts                          13a
     D  LstSts                        1a
     D                                1a
     D  InfLen                       10i 0
     D  Rcd1                         10i 0
     D                               40a

     **-- User information:
     D USRI0300        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  UsrPrf                       10a
     D  ObjAudVal                    10a   Overlay( USRI0300: 501 )
     D  UsrAudVal                          Overlay( USRI0300: 511 )
     D                                     LikeDs( AudLvl )
     **-- User information:
     D AUTU0150        Ds                  Qualified
     D  UsrPrf                       10a
     D  UsrGrpI                       1a
     D  GrpMbrI                       1a
     D  TxtDsc                       50a

     **-- Open list of authorized users:
     D LstAutUsr       Pr                  ExtPgm( 'QGYOLAUS' )
     D  RcvVar                    65535a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  LstInf                       80a
     D  NbrRcdRtn                    10i 0 Const
     D  FmtNam                        8a   Const
     D  SltCri                       10a   Const
     D  GrpNam                       10a   Const
     D  Error                      1024a          Options( *VarSize )
     D  UsrPrf                       10a   Const  Options( *NoPass )
     **-- Retrieve user information:
     D RtvUsrInf       Pr                  ExtPgm( 'QSYRUSRI' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                       10a   Const
     D  UsrPrf                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve user authority to object:
     D RtvUsrAut       Pr                  ExtPgm( 'QSYRUSRA' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  UsrPrf                       10a   Const
     D  ObjNamQ                      20a   Const
     D  ObjTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     D  AspDev                       10a          Options( *NoPass )
     **-- Check special authority
     D ChkSpcAut       Pr                  ExtPgm( 'QSYCUSRS' )
     D  AutInf                        1a
     D  UsrPrf                       10a   Const
     D  SpcAut                       10a   Const  Dim( 8 )  Options( *VarSize )
     D  NbrAut                       10i 0 Const
     D  CalLvl                       10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve job information:
     D RtvJobInf       Pr                  ExtPgm( 'QUSRJOBI' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  JobNamQ                      26a   Const
     D  JobIntId                     16a   Const
     D  Error                     32767a          Options( *NoPass: *VarSize )
     **-- Retrieve object descrlenion:
     D RtvObjD         Pr                  ExtPgm( 'QUSROBJD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  ObjNamQ                      20a   Const
     D  ObjTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve database file description:
     D RtvDbfDsc       Pr                  ExtPgm( 'QDBRTVFD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FilNamRtn_q                  20a
     D  FmtNam                        8a   Const
     D  FilNam_q                     20a   Const
     D  RcdFmtNam                    10a   Const
     D  OvrPrc                        1a   Const
     D  System                       10a   Const
     D  FmtTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve net attribute:
     D RtvNetAtr       Pr                  ExtPgm( 'QWCRNETA' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  NbrNetAtr                    10i 0 Const
     D  NetAtr                       10a   Const  Dim( 256 )
     D                                            Options( *VarSize )
     D  Error                     32767a          Options( *VarSize )
     **-- Process commands:
     D PrcCmds         Pr                  ExtPgm( 'QCAPCMD' )
     D  SrcCmd                    32702a   Const  Options( *VarSize )
     D  SrcCmdLen                    10i 0 Const
     D  OptCtlBlk                    20a   Const
     D  OptCtlBlkLen                 10i 0 Const
     D  OptCtlBlkFmt                  8a   Const
     D  ChgCmd                    32767a          Options( *VarSize )
     D  ChgCmdLen                    10i 0 Const
     D  ChgCmdLenAvl                 10i 0
     D  Error                     32767a          Options( *VarSize )
     **-- Move program messages:
     D MovPgmMsg       Pr                  ExtPgm( 'QMHMOVPM' )
     D  MsgKey                        4a   Const
     D  MsgTyps                      10a   Const  Options( *VarSize )  Dim( 4 )
     D  NbrMsgTyps                   10i 0 Const
     D  ToCalStkE                  4102a   Const  Options( *VarSize )
     D  ToCalStkCnt                  10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     D  ToCalStkLen                  10i 0 Const  Options( *NoPass )
     D  ToCalStkEq                   20a   Const  Options( *NoPass )
     D  ToCalStkEdt                  10a   Const  Options( *NoPass )
     D  FrCalStkEad                    *   Const  Options( *NoPass )
     D  FrCalStkCnt                  10i 0 Const  Options( *NoPass )
     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      128a   Const
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                     32767a          Options( *VarSize )

     **-- Get open list entry:
     D GetOplEnt       Pr                  ExtPgm( 'QGYGTLE' )
     D  RcvVar                    65535a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  Handle                        4a   Const
     D  LstInf                       80a
     D  NbrRcdRtn                    10i 0 Const
     D  RtnRcdNbr                    10i 0 Const
     D  Error                      1024a          Options( *VarSize )
     **-- Close list:
     D CloseLst        Pr                  ExtPgm( 'QGYCLST' )
     D  Handle                        4a   Const
     D  Error                      1024a          Options( *VarSize )

     **-- Open display application:
     D OpnDspApp       Pr                  ExtPgm( 'QUIOPNDA' )
     D  AppHdl                        8a
     D  PnlGrp_q                     20a   Const
     D  AppScp                       10i 0 Const
     D  ExtPrmIfc                    10i 0 Const
     D  FulScrHlp                     1a   Const
     D  Error                     32767a          Options( *VarSize )
     D  OpnDtaRcv                   128a          Options( *NoPass: *VarSize )
     D  OpnDtaRcvLen                 10i 0 Const  Options( *NoPass )
     D  OpnDtaRcvAvl                 10i 0        Options( *NoPass )
     **-- Add print application:
     D AddPrtApp       Pr                  ExtPgm( 'QUIADDPA' )
     D  AppHdl                        8a   Const
     D  PrtDevF_q                    20a   Const
     D  AltFilNam                    10a   Const
     D  ShrOpnDtaPth                  1a   Const
     D  UsrDta                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     D  OpnDtaRcv                   128a          Options( *NoPass: *VarSize )
     D  OpnDtaRcvLen                 10i 0 Const  Options( *NoPass )
     D  OpnDtaRcvAvl                 10i 0        Options( *NoPass )
     **-- Open print application:
     D OpnPrtApp       Pr                  ExtPgm( 'QUIOPNPA' )
     D  AppHdl                        8a
     D  PnlGrp_q                     20a   Const
     D  AppScp                       10i 0 Const
     D  ExtPrmIfc                    10i 0 Const
     D  PrtDevF_q                    20a   Const
     D  AltFilNam                    10a   Const
     D  ShrOpnDtaPth                  1a   Const
     D  UsrDta                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     D  OpnDtaRcv                   128a          Options( *NoPass: *VarSize )
     D  OpnDtaRcvLen                 10i 0 Const  Options( *NoPass )
     D  OpnDtaRcvAvl                 10i 0        Options( *NoPass )
     **-- Display panel:
     D DspPnl          Pr                  ExtPgm( 'QUIDSPP' )
     D  AppHdl                        8a   Const
     D  FncRqs                       10i 0
     D  PnlNam                       10a   Const
     D  ReDspOpt                      1a   Const
     D  Error                     32767a          Options( *VarSize )
     D  UsrTsk                        1a   Const  Options( *NoPass )
     D  CalStkCnt                    10i 0 Const  Options( *NoPass )
     D  CalMsgQue                   256a   Const  Options( *NoPass: *VarSize )
     D  MsgKey                        4a   Const  Options( *NoPass )
     D  CsrPosOpt                     1a   Const  Options( *NoPass )
     D  FinLstEnt                     4a   Const  Options( *NoPass )
     D  ErrLstEnt                     4a   Const  Options( *NoPass )
     D  WaitTim                      10i 0 Const  Options( *NoPass )
     D  CalMsgQueLen                 10i 0 Const  Options( *NoPass )
     D  CalQlf                       20a   Const  Options( *NoPass )
     **-- Print panel:
     D PrtPnl          Pr                  ExtPgm( 'QUIPRTP' )
     D  AppHdl                        8a   Const
     D  PrtPnlNam                    10a   Const
     D  EjtOpt                        1a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Put dialog variable:
     D PutDlgVar       Pr                  ExtPgm( 'QUIPUTV' )
     D  AppHdl                        8a   Const
     D  VarBuf                    32767a   Const  Options( *VarSize )
     D  VarBufLen                    10i 0 Const
     D  VarRcdNam                    10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Get dialog variable:
     D GetDlgVar       Pr                  ExtPgm( 'QUIGETV' )
     D  AppHdl                        8a   Const
     D  VarBuf                    32767a          Options( *VarSize )
     D  VarBufLen                    10i 0 Const
     D  VarRcdNam                    10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Add list entry:
     D AddLstEnt       Pr                  ExtPgm( 'QUIADDLE' )
     D  AppHdl                        8a   Const
     D  VarBuf                    32767a   Const  Options( *VarSize )
     D  VarBufLen                    10i 0 Const
     D  VarRcdNam                    10a   Const
     D  LstNam                       10a   Const
     D  EntLocOpt                     4a   Const
     D  LstEntHdl                     4a
     D  Error                     32767a          Options( *VarSize )
     **-- Get list entry:
     D GetLstEnt       Pr                  ExtPgm( 'QUIGETLE' )
     D  AppHdl                        8a   Const
     D  VarBuf                    32767a   Const  Options( *VarSize )
     D  VarBufLen                    10i 0 Const
     D  VarRcdNam                    10a   Const
     D  LstNam                       10a   Const
     D  PosOpt                        4a   Const
     D  CpyOpt                        1a   Const
     D  SltCri                       20a   Const
     D  SltHdl                        4a   Const
     D  ExtOpt                        1a   Const
     D  LstEntHdl                     4a
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve list attributes:
     D RtvLstAtr       Pr                  ExtPgm( 'QUIRTVLA' )
     D  AppHdl                        8a   Const
     D  LstNam                       10a   Const
     D  AtrRcv                    32767a          Options( *VarSize )
     D  AtrRcvLen                    10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     **-- Set list attributes:
     D SetLstAtr       Pr                  ExtPgm( 'QUISETLA' )
     D  AppHdl                        8a   Const
     D  LstNam                       10a   Const
     D  LstCon                        4a   Const
     D  ExtPgmVar                    10a   Const
     D  DspPos                        4a   Const
     D  AlwTrim                       1a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Delete list:
     D DltLst          Pr                  ExtPgm( 'QUIDLTL' )
     D  AppHdl                        8a   Const
     D  LstNam                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Close application:
     D CloApp          Pr                  ExtPgm( 'QUICLOA' )
     D  AppHdl                        8a   Const
     D  CloOpt                        1a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Register activation group exit:
     D CEE4RAGE        Pr
     D  procedure                      *   ProcPtr  Const
     D  feedback                     12a   Options( *omit )

     **-- Get job type:
     D GetJobTyp       Pr             1a
     **-- Get net attribute:
     D GetNetAtr       Pr          4096a   Varying
     D  PxNetAtr                     10a   Const
     **-- Check object existence:
     D ChkObj          Pr              n
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const
     **-- Get object library:
     D GetObjLib       Pr            10a
     D  PxObjNam_q                         LikeDs( ObjNam_q )
     D  PxObjTyp                     10a   Const
     **-- Get object attribute:
     D GetObjAtr       Pr            10a
     D  PxObjNam_q                         LikeDs( ObjNam_q )
     D  PxObjTyp                     10a   Const
     **-- Verify format level:
     D VfyFmtLvl       Pr              n
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxFmtLvlId                   13a   Const
     **-- Clear physical file member:
     D ClrPfm          Pr            10i 0
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxMbrNam                     10a   Const  Varying  Options( *Trim )
     **-- Process command:
     D PrcCmd          Pr            10i 0
     D  PxCmdStr                   4096a   Const  Varying
     **-- Check audit value:
     D ChkAudVal       Pr             1a
     D  PxChkAut                     10a   Value
     D  PxAudVal                           Value  LikeDs( AudVal )
     **-- Verify user audit level:
     D VfyUsrAud       Pr              n
     D  PxRefAud                           Value  LikeDs( AudLvl )
     D  PxUsrAud                           Value  LikeDs( AudLvl )
     **-- Compare user audit level:
     D CmpUsrAud       Pr              n
     D  PxRefAud                           Value  LikeDs( AudLvl )
     D  PxUsrAud                           Value  LikeDs( AudLvl )
     **-- Get user class:
     D GetUsrCls       Pr            10a
     D  PxUsrPrf                     10a   Value
     **-- Get user audit values:
     D GetUsrAud       Pr                  LikeDs( AudLvl )
     D  PxUsrPrf                     10a   Value
     **-- Get group profile:
     D GetGrpPrf       Pr            10a
     D  PxUsrPrf                     10a   Value
     **-- Check error:
     D Check_error     Pr
     D  rc                           10i 0 Value
     D  env                                Like( SQLHENV )   Value
     D  conn                               Like( SQLHDBC )   Value
     D  stmt                               Like( SQLHSTMT )  Value
     D  function                     50a   Varying  Const
     **-- Send status message:
     D SndStsMsg       Pr            10i 0
     D  PxMsgDta                   1024a   Const  Varying
     **-- Send completion message:
     D SndCmpMsg       Pr            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **-- Send diagnostic message:
     D SndDiagMsg      Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **-- Cleanup resources:
     D Cleanup         Pr

     **-- Entry parameters:
     D ObjNam_q        Ds                  Qualified
     D  ObjNam                       10a
     D  ObjLib                       10a
     **
     D AudVal          Ds                  Qualified
     D  NbrAud                        5i 0
     D  AudVal                       10a   Dim( 30 )
     **
     D SEC105          Pr
     D  PxUsrPrf                     10a
     D  PxUsrCls                     10a
     D  PxAudVal                           LikeDs( AudVal )
     D  PxObjAud                     10a
     D  PxOutOpt                      3a
     D  PxOutFil_q                         LikeDs( ObjNam_q )
     D  PxRplRcd                      1a
     **
     D SEC105          Pi
     D  PxUsrPrf                     10a
     D  PxUsrCls                     10a
     D  PxAudVal                           LikeDs( AudVal )
     D  PxObjAud                     10a
     D  PxOutOpt                      3a
     D  PxOutFil_q                         LikeDs( ObjNam_q )
     D  PxRplRcd                      1a

      /Free

        CEE4RAGE( %Paddr( Cleanup ): *Omit );

        SpcAutLst( 1 ) = '*AUDIT';

        ChkSpcAut( AutFlg
                 : PgmSts.UsrPrf
                 : SpcAutLst
                 : 1
                 : ADP_PRV_INVLVL
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero  Or AutFlg = 'N';
          SndEscMsg( 'CPFB304': 'QCPFMSG': NULL );
        EndIf;

        Select;
        When  PxOutOpt = 'DSP'  And  GetJobTyp() = TYP_INTER;

          OpnDspApp( UIM.AppHdl
                   : PNLGRP_Q
                   : SCP_AUT_RCL
                   : PRM_IFC_0
                   : HLP_WDW
                   : ERRC0100
                   );

        When  PxOutOpt = 'FIL';
          ExSr  InzOutFil;

        Other;
          OpnPrtApp( UIM.AppHdl
                   : PNLGRP_Q
                   : SCP_AUT_RCL
                   : PRM_IFC_0
                   : APP_PRTF
                   : SPLF_NAM
                   : ODP_SHR
                   : SPLF_USRDTA
                   : ERRC0100
                   );
        EndSl;

        If  ERRC0100.BytAvl > *Zero;
          ExSr  EscApiErr;
        EndIf;

        SndStsMsg( 'Retrieving user audit information, please wait...' );

        If  PxOutOpt = 'FIL';
          ExSr  InzSqlCli;
          ExSr  BldUsrLst2;
          ExSr  EndSqlCli;

        Else;
          ExSr  BldHdrRcd;
          ExSr  BldUsrLst;

          If  PxOutOpt = 'DSP'  And  GetJobTyp() = TYP_INTER;
            ExSr  DspLst;
          Else;
            ExSr  WrtLst;
          EndIf;
        EndIf;

        *InLr = *On;
        Return;


        BegSr  EscApiErr;

          If  ERRC0100.BytAvl < OFS_MSGDTA;
            ERRC0100.BytAvl = OFS_MSGDTA;
          EndIf;

          SndEscMsg( ERRC0100.MsgId
                   : 'QCPFMSG'
                   : %Subst( ERRC0100.MsgDta: 1: ERRC0100.BytAvl - OFS_MSGDTA )
                   );

        EndSr;

        BegSr  DspLst;

          DoU  UIM.FncRqs = FNC_EXIT  Or  UIM.FncRqs = FNC_CNL;

            DspPnl( UIM.AppHdl: UIM.FncRqs: PNLGRP: RDS_OPT_INZ: ERRC0100 );

            If  ERRC0100.BytAvl > *Zero;
              ExSr  EscApiErr;
            EndIf;

            GetDlgVar( UIM.AppHdl
                     : HdrRcd
                     : %Size( HdrRcd )
                     : 'HDRRCD'
                     : ERRC0100
                     );

            Select;
            When  UIM.FncRqs = KEY_F05  And  UIM.EntLocOpt = 'NEXT';
              ExSr  GetLstPos;
              ExSr  DltUsrLst;

            When  WrkUsr <> HdrRcd.WrkUsr;
              ExSr  DltUsrLst;
            EndSl;

            Select;
            When  UIM.FncRqs = KEY_F05;
              ExSr  RstHdrRcd;
              ExSr  BldHdrRcd;
              ExSr  BldUsrLst;
              ExSr  SetLstPos;

            When  WrkUsr <> HdrRcd.WrkUsr;
              WrkUsr = HdrRcd.WrkUsr;

              ExSr  BldHdrRcd;
              ExSr  BldUsrLst;
            EndSl;

            Select;
            When  UIM.FncRqs = RTN_ENTER  And
                  UIM.EntLocOpt = 'NEXT'  And
                  HdrRcd.PosUsr > *Blanks;

              ExSr  FndLstPos;

            When  UIM.FncRqs = KEY_F17;
              ExSr  PosLstTop;

            When  UIM.FncRqs = KEY_F18;
              ExSr  PosLstBot;
            EndSl;

          EndDo;

        EndSr;

        BegSr  WrtLst;

          PrtPnl( UIM.AppHdl
                : 'PRTHDR'
                : EJECT_NO
                : ERRC0100
                );

          PrtPnl( UIM.AppHdl
                : 'PRTLST'
                : EJECT_NO
                : ERRC0100
                );

          SndCmpMsg( 'List has been printed.' );

        EndSr;

        BegSr  BldUsrLst;

          UIM.EntLocOpt = 'FRST';

          ExSr  BldUsrLst2;

          SetLstAtr( UIM.AppHdl
                   : 'DTLLST'
                   : LIST_COMP
                   : EXIT_SAME
                   : POS_TOP
                   : TRIM_SAME
                   : ERRC0100
                   );

        EndSr;

        BegSr  BldUsrLst2;

          LstApi.RtnRcdNbr = 1;
          LstApi.SltCri = '*ALL';
          LstApi.GrpNam = '*NONE';

          If  WrkUsr = '*CURRENT';
            AUTU0150.UsrPrf = PgmSts.CurUsr;

            ExSr  PrcLstEnt;

          Else;
            LstApi.UsrPrf = WrkUsr;

            LstAutUsr( AUTU0150
                     : %Size( AUTU0150 )
                     : LstInf
                     : 1
                     : 'AUTU0150'
                     : LstApi.SltCri
                     : LstApi.GrpNam
                     : ERRC0100
                     : LstApi.UsrPrf
                     );

            If  ERRC0100.BytAvl = *Zero;

              DoW  LstInf.LstSts <> '2'  Or
                   LstInf.RcdNbrTot >= LstApi.RtnRcdNbr;

                ExSr  PrcLstEnt;

                LstApi.RtnRcdNbr = LstApi.RtnRcdNbr + 1;

                GetOplEnt( AUTU0150
                         : %Size( AUTU0150 )
                         : LstInf.Handle
                         : LstInf
                         : 1
                         : LstApi.RtnRcdNbr
                         : ERRC0100
                         );

                If  ERRC0100.BytAvl > *Zero;
                  Leave;
                EndIf;

              EndDo;

              CloseLst( LstInf.Handle: ERRC0100 );
            EndIf;
          EndIf;

        EndSr;

        BegSr  PrcLstEnt;

          RtvUsrInf( USRI0300
                   : %Size( USRI0300 )
                   : 'USRI0300'
                   : AUTU0150.UsrPrf
                   : ERRC0100
                   );

          If  ERRC0100.BytAvl = *Zero;

            If  PxUsrCls = '*ANY' Or  PxUsrCls = GetUsrCls( AUTU0150.UsrPrf );

              If  PxObjAud = '*ANY' Or  PxObjAud = USRI0300.ObjAudVal;

                If  VfyUsrAud( RefAudLvl: USRI0300.UsrAudVal ) = *On;

                  ExSr  PutLstEnt;
                EndIf;
              EndIf;
            EndIf;
          EndIf;

        EndSr;

        BegSr  PutLstEnt;

          Clear  LstEnt;

          LstEnt.Option = *Zero;

          LstEnt.UsrPrf = AUTU0150.UsrPrf;
          LstEnt.UsrCls = GetUsrCls( AUTU0150.UsrPrf );
          LstEnt.GrpPrf = GetGrpPrf( AUTU0150.UsrPrf );

          Eval-Corr  LstEnt = USRI0300;

          If  PxOutOpt = 'FIL';
            Exsr  RunSqlStm;

          Else;
            AddLstEnt( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : 'DTLRCD'
                     : 'DTLLST'
                     : UIM.EntLocOpt
                     : UIM.LstHdl
                     : ERRC0100
                     );

            UIM.EntLocOpt = 'NEXT';
          EndIf;

        EndSr;

        BegSr  GetLstPos;

          RtvLstAtr( UIM.AppHdl: 'DTLLST': LstAtr: %Size( LstAtr ): ERRC0100 );

          If  LstAtr.DspPos <> 'TOP';

            GetLstEnt( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : 'DTLRCD'
                     : 'DTLLST'
                     : 'HNDL'
                     : 'Y'
                     : *Blanks
                     : LstAtr.DspPos
                     : 'N'
                     : UIM.EntHdl
                     : ERRC0100
                     );

            LstEntPos = LstEnt;
          EndIf;

        EndSr;

        BegSr  SetLstPos;

          If  LstAtr.DspPos <> 'TOP';

            LstEnt = LstEntPos;

            PutDlgVar( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : 'DTLRCD'
                     : ERRC0100
                     );

            GetLstEnt( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : '*NONE'
                     : 'DTLLST'
                     : 'FSLT'
                     : 'N'
                     : 'EQ        USRPRF'
                     : *Blanks
                     : 'N'
                     : UIM.EntHdl
                     : ERRC0100
                     );

            If  ERRC0100.BytAvl = *Zero;

              SetLstAtr( UIM.AppHdl
                       : 'DTLLST'
                       : LIST_SAME
                       : EXIT_SAME
                       : UIM.EntHdl
                       : TRIM_SAME
                       : ERRC0100
                       );

            EndIf;
          EndIf;

        EndSr;

        BegSr  FndLstPos;

          LstEnt.UsrPrf = HdrRcd.PosUsr;

          PutDlgVar( UIM.AppHdl
                   : LstEnt
                   : %Size( LstEnt )
                   : 'DTLRCD'
                   : ERRC0100
                   );

          GetLstEnt( UIM.AppHdl
                   : LstEnt
                   : %Size( LstEnt )
                   : 'DTLRCD'
                   : 'DTLLST'
                   : 'FSLT'
                   : 'Y'
                   : 'GE        USRPRF'
                   : *Blanks
                   : 'N'
                   : UIM.EntHdl
                   : ERRC0100
                   );

          Select;
          When  ERRC0100.BytAvl > *Zero;

            GetLstEnt( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : '*NONE'
                     : 'DTLLST'
                     : 'LAST'
                     : 'N'
                     : *Blanks
                     : *Blanks
                     : 'N'
                     : UIM.EntHdl
                     : ERRC0100
                     );

          When  %Scan( %Trim( HdrRcd.PosUsr ): LstEnt.UsrPrf ) <> 1;

            GetLstEnt( UIM.AppHdl
                     : LstEnt
                     : %Size( LstEnt )
                     : '*NONE'
                     : 'DTLLST'
                     : 'PREV'
                     : 'N'
                     : *Blanks
                     : *Blanks
                     : 'N'
                     : UIM.EntHdl
                     : ERRC0100
                     );

            If  ERRC0100.BytAvl > *Zero;

              GetLstEnt( UIM.AppHdl
                       : LstEnt
                       : %Size( LstEnt )
                       : '*NONE'
                       : 'DTLLST'
                       : 'FRST'
                       : 'N'
                       : *Blanks
                       : *Blanks
                       : 'N'
                       : UIM.EntHdl
                       : ERRC0100
                       );
            EndIf;
          EndSl;

          If  ERRC0100.BytAvl = *Zero;

            SetLstAtr( UIM.AppHdl
                     : 'DTLLST'
                     : LIST_SAME
                     : EXIT_SAME
                     : UIM.EntHdl
                     : TRIM_SAME
                     : ERRC0100
                     );

          EndIf;

          HdrRcd.PosUsr = *Blanks;

        EndSr;

        BegSr  PosLstTop;

          SetLstAtr( UIM.AppHdl
                   : 'DTLLST'
                   : LIST_SAME
                   : EXIT_SAME
                   : POS_TOP
                   : TRIM_SAME
                   : ERRC0100
                   );

        EndSr;

        BegSr  PosLstBot;

          SetLstAtr( UIM.AppHdl
                   : 'DTLLST'
                   : LIST_SAME
                   : EXIT_SAME
                   : POS_BOT
                   : TRIM_SAME
                   : ERRC0100
                   );

        EndSr;

        BegSr  BldHdrRcd;

          HdrRcd.SysDat = %Char( %Date( SysDts ): *CYMD0 );
          HdrRcd.SysTim = %Char( %Time( SysDts ): *HMS0 );
          HdrRcd.TimZon = '*SYS';

          PutDlgVar( UIM.AppHdl: HdrRcd: %Size( HdrRcd ): 'HDRRCD': ERRC0100 );

        EndSr;

        BegSr  RstHdrRcd;

          HdrRcd.WrkUsr = WrkUsr;
          HdrRcd.PosUsr = *Blanks;

        EndSr;

        BegSr  DltUsrLst;

          DltLst( UIM.AppHdl: 'DTLLST': ERRC0100 );

        EndSr;

        BegSr  InzOutFil;

          SysName = GetNetAtr( 'SYSNAME' );

          If  PxOutFil_q.ObjLib = '*LIBL';
            PxOutFil_q.ObjLib = GetObjLib( PxOutFil_q: '*FILE' );
          EndIf;

          Select;
          When  ChkObj( PxOutFil_q: '*FILE' ) = *Off;
            CrtOutFil = *On;

          When  VfyFmtLvl( PxOutFil_q: FMT_LVLID ) = *Off;
            SndEscMsg( 'CPF9865': 'QCPFMSG': PxOutFil_q );

          When  PxRplRcd = '1';
            ClrPfm( PxOutFil_q: '*FIRST' );
          EndSl;

        EndSr;

        BegSr  RunSqlStm;

          SQLValue.SysNam = SysName;
          SQLValue.SysDts = SysDts;

          Eval-Corr  SQLValue = LstEnt;

          rc = SQLExecute( stmt );

          Check_error( rc: env: conn: stmt: 'SQLExecute()' );

        EndSr;

        BegSr  InzSqlCli;

          SQLTable = %TrimR( PxOutFil_q.ObjLib ) + '/' +
                     %TrimR( PxOutFil_q.ObjNam );

          SQLAllocEnv( env );

          SQLSetEnvAttrI( env
                        : SQL_ATTR_ENVHNDL_COUNTER
                        : SQL_TRUE
                        : %Size( SQLINTEGER )
                        );

          SQLSetEnvAttrI( env
                        : SQL_ATTR_OUTPUT_NTS
                        : SQL_FALSE
                        : %size( SQLINTEGER )
                        );

          SQLAllocConnect( env: conn );

          SQLSetConnectAttrI( conn
                            : SQL_ATTR_DBC_SYS_NAMING
                            : SQL_TRUE
                            : %Size( SQLINTEGER )
                            );

          SQLSetConnectAttrI( conn
                            : SQL_ATTR_COMMIT
                            : SQL_TXN_NO_COMMIT
                            : %Size( SQLINTEGER )
                            );

          rc = SQLConnect( conn
                         : '*LOCAL'
                         : SQL_NTS
                         : *Null
                         : SQL_NTS
                         : *Null
                         : SQL_NTS
                         );

          Check_error( rc: env: conn: stmt: 'SQLConnect()' );

          If  CrtOutFil;
            ExSr  RunFilCrt;
          EndIf;

          SQLAllocStmt( conn : stmt );

          SQLStmt = 'INSERT INTO ' + SQLTable + ' '                    +
                    '(SYSNAM, SYSDTS, USRPRF, USRCLS, GRPPRF, AFOBJA,' +
                    ' AFCMDA, AFCRTA, AFDLTA, AFJBDT, AFOBMG, AFOFSV,' +
                    ' AFPGAD, AFSVRS, AFSECA, AFSRVA, AFSPDT, AFSYMG,' +
                    ' AFOPTA, AFAUTF, AFJBBA, AFJBCU, AFNTBA, AFNTCL,' +
                    ' AFNTCM, AFNETF, AFNTSC, AFPGMF, AFPRDT, AFSCCF,' +
                    ' AFSCDS, AFSCIP, AFSCNA, AFSCRU, AFSCSD, AFSCVF,' +
                    ' AFSCVL)'                                         +
                    ' VALUES(?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,' +
                    ' ?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?)';

          rc = SQLPrepare( stmt: SQLStmt: SQL_NTS );

          Check_error( rc: env: conn: stmt: 'SQLPrepare()' );

          ExSr  BndPrmMrk;

        EndSr;

        BegSr  BndPrmMrk;

          rc = SQLBindParameter( stmt
                               : 1
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.SysNam )
                               : *Zero
                               : %Addr( SQLValue.SysNam )
                               : SQL_IGN_INT
                               : lenParm1
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 2
                               : SQL_PARAM_INPUT
                               : SQL_TIMESTAMP
                               : SQL_TIMESTAMP
                               : %Len( SQLValue.SysDts )
                               : *Zero
                               : %Addr( SQLValue.SysDts )
                               : SQL_IGN_INT
                               : *Omit
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 3
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.UsrPrf )
                               : *Zero
                               : %Addr( SQLValue.UsrPrf )
                               : SQL_IGN_INT
                               : lenParm3
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 4
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.UsrCls )
                               : *Zero
                               : %Addr( SQLValue.UsrCls )
                               : SQL_IGN_INT
                               : lenParm4
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 5
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.GrpPrf )
                               : *Zero
                               : %Addr( SQLValue.GrpPrf )
                               : SQL_IGN_INT
                               : lenParm5
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 6
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.ObjAudVal )
                               : *Zero
                               : %Addr( SQLValue.ObjAudVal )
                               : SQL_IGN_INT
                               : lenParm6
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 7
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Cmd )
                               : SQL_IGN_INT
                               : lenParm7
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 8
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Create )
                               : SQL_IGN_INT
                               : lenParm8
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 9
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Delete )
                               : SQL_IGN_INT
                               : lenParm9
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 10
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.JobDta )
                               : SQL_IGN_INT
                               : lenParm10
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 11
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.ObjMgt )
                               : SQL_IGN_INT
                               : lenParm11
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 12
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.OfcSrv )
                               : SQL_IGN_INT
                               : lenParm12
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 13
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.PgmAdp )
                               : SQL_IGN_INT
                               : lenParm13
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 14
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SavRst )
                               : SQL_IGN_INT
                               : lenParm14
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 15
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Security )
                               : SQL_IGN_INT
                               : lenParm15
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 16
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Service )
                               : SQL_IGN_INT
                               : lenParm16
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 17
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SplfDta )
                               : SQL_IGN_INT
                               : lenParm17
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 18
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SysMgt )
                               : SQL_IGN_INT
                               : lenParm18
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 19
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.Optical )
                               : SQL_IGN_INT
                               : lenParm19
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 20
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.AutFail )
                               : SQL_IGN_INT
                               : lenParm20
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 21
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.JobBas )
                               : SQL_IGN_INT
                               : lenParm21
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 22
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.JobChgUsr )
                               : SQL_IGN_INT
                               : lenParm22
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 23
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.NetBas )
                               : SQL_IGN_INT
                               : lenParm23
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 24
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.NetClu )
                               : SQL_IGN_INT
                               : lenParm24
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 25
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.NetCmn )
                               : SQL_IGN_INT
                               : lenParm25
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 26
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.NetFail )
                               : SQL_IGN_INT
                               : lenParm26
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 27
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.NetSck )
                               : SQL_IGN_INT
                               : lenParm27
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 28
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.PgmFail )
                               : SQL_IGN_INT
                               : lenParm28
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 29
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.PrtDta )
                               : SQL_IGN_INT
                               : lenParm29
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 30
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecCfg )
                               : SQL_IGN_INT
                               : lenParm30
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 31
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecDirSrv )
                               : SQL_IGN_INT
                               : lenParm31
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 32
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecIpc )
                               : SQL_IGN_INT
                               : lenParm32
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 33
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecNas )
                               : SQL_IGN_INT
                               : lenParm33
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 34
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecRun )
                               : SQL_IGN_INT
                               : lenParm34
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 35
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecSckD )
                               : SQL_IGN_INT
                               : lenParm35
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 36
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecVfy )
                               : SQL_IGN_INT
                               : lenParm36
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

          rc = SQLBindParameter( stmt
                               : 37
                               : SQL_PARAM_INPUT
                               : SQL_CHAR
                               : SQL_CHAR
                               : %Size( SQLValue.AudFlg )
                               : *Zero
                               : %Addr( SQLValue.UsrAudVal.SecVldL )
                               : SQL_IGN_INT
                               : lenParm37
                               );

          Check_error( rc: env: conn: stmt: 'SQLBindParameter()' );

        EndSr;

        BegSr  RunFilCrt;

          rc = SQLAllocStmt( conn : stmt );

          Check_error( rc: env: conn: stmt: 'SQLAllocStmt()' );

          SQLStmt = 'CREATE TABLE ' + SQLTable + ' ('               +
                    'SYSNAM CHAR (8)      NOT NULL WITH DEFAULT, '  +
                    'SYSDTS TIMESTAMP     NOT NULL WITH DEFAULT, '  +
                    'USRPRF CHAR  (10)    NOT NULL WITH DEFAULT, '  +
                    'USRCLS CHAR  (10)    NOT NULL WITH DEFAULT, '  +
                    'GRPPRF CHAR  (10)    NOT NULL WITH DEFAULT, '  +
                    'AFOBJA CHAR  (10)    NOT NULL WITH DEFAULT, '  +
                    'AFCMDA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFCRTA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFDLTA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFJBDT CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFOBMG CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFOFSV CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFPGAD CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSVRS CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSECA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSRVA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSPDT CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSYMG CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFOPTA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFAUTF CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFJBBA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFJBCU CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFNTBA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFNTCL CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFNTCM CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFNETF CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFNTSC CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFPGMF CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFPRDT CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCCF CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCDS CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCIP CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCNA CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCRU CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCSD CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCVF CHAR   (1)    NOT NULL WITH DEFAULT, '  +
                    'AFSCVL CHAR   (1)    NOT NULL WITH DEFAULT'    +
                    ') RCDFMT USRAUDR';

          rc = SQLExecDirect( stmt: SQLStmt: SQL_NTS );

          Check_error( rc: env: conn: stmt: 'SQLExecDirect()' );

          SQLStmt = 'LABEL ON TABLE ' + SQLTable + ' IS '           +
                    '''User auditing output file''';

          SQLExecDirect( stmt: SQLStmt: SQL_NTS );

          SQLStmt = 'LABEL ON COLUMN ' + SQLTable + ' '             +
                    '(SYSNAM IS ''System name'', '                  +
                    'SYSDTS IS ''System time'', '                   +
                    'USRPRF IS ''User profile'', '                  +
                    'USRCLS IS ''User class'', '                    +
                    'GRPPRF IS ''Group profile'', '                 +
                    'AFOBJA IS ''Object auditing     value'', '     +
                    'AFCMDA IS ''*CMD user audit'', '               +
                    'AFCRTA IS ''*CREATE user audit'', '            +
                    'AFDLTA IS ''*DELETE user audit'', '            +
                    'AFJBDT IS ''*JOBDTA user audit'', '            +
                    'AFOBMG IS ''*OBJMGT user audit'', '            +
                    'AFOFSV IS ''*OFCSRV user audit'', '            +
                    'AFPGAD IS ''*PGMADP user audit'', '            +
                    'AFSVRS IS ''*SAVRST user audit'', '            +
                    'AFSECA IS ''*SECURITY user      audit'', '     +
                    'AFSRVA IS ''*SERVICE user audit'', '           +
                    'AFSPDT IS ''*SPLFDTA user audit'', '           +
                    'AFSYMG IS ''*SYSMGT user audit'', '            +
                    'AFOPTA IS ''*OPTICAL user audit'', '           +
                    'AFAUTF IS ''*AUTFAIL user audit'', '           +
                    'AFJBBA IS ''*JOBBAS user audit'', '            +
                    'AFJBCU IS ''*JOBCHGUSR user     audit'', '     +
                    'AFNTBA IS ''*NETBAS user audit'', '            +
                    'AFNTCL IS ''*NETCLU user audit'', '            +
                    'AFNTCM IS ''*NETCMN user audit'', '            +
                    'AFNETF IS ''*NETFAIL user audit'', '           +
                    'AFNTSC IS ''*NETSCK user audit'', '            +
                    'AFPGMF IS ''*PGMFAIL user audit'', '           +
                    'AFPRDT IS ''*PRTDTA user audit'', '            +
                    'AFSCCF IS ''*SECCFG user audit'', '            +
                    'AFSCDS IS ''*SECDIRSRV user     audit'', '     +
                    'AFSCIP IS ''*SECIPC user audit'', '            +
                    'AFSCNA IS ''*SECNAS user audit'', '            +
                    'AFSCRU IS ''*SECRUN user audit'', '            +
                    'AFSCSD IS ''*SECSCKD user audit'', '           +
                    'AFSCVF IS ''*SECVFY user audit'', '            +
                    'AFSCVL IS ''*SECVLDL user audit'' )';

          SQLExecDirect( stmt: SQLStmt: SQL_NTS );

          SQLStmt = 'LABEL ON COLUMN ' + SQLTable + ' '             +
                    '(SYSNAM TEXT IS ''System name'', '             +
                    'SYSDTS TEXT IS ''Timestamp'', '                +
                    'USRPRF TEXT IS ''Profile name'', '             +
                    'USRCLS TEXT IS ''Category'', '                 +
                    'GRPPRF TEXT IS ''Profile name'', '             +
                    'AFOBJA TEXT IS ''Audit value'', '              +
                    'AFCMDA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFCRTA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFDLTA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFJBDT TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFOBMG TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFOFSV TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFPGAD TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSVRS TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSECA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSRVA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSPDT TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSYMG TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFOPTA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFAUTF TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFJBBA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFJBCU TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFNTBA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFNTCL TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFNTCM TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFNETF TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFNTSC TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFPGMF TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFPRDT TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCCF TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCDS TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCIP TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCNA TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCRU TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCSD TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCVF TEXT IS ''Audit flag; Y=Yes, N=No'', '  +
                    'AFSCVL TEXT IS ''Audit flag; Y=Yes, N=No'' )';

          SQLExecDirect( stmt: SQLStmt: SQL_NTS );

          SQLFreeStmt( stmt : SQL_DROP );

        EndSr;

        BegSr  EndSqlCli;

          Cleanup();

          If  CrtOutFil;
            SndCmpMsg( 'User auditing file '                    +
                       %TrimR( PxOutFil_q.ObjNam )              +
                       ' in '                                   +
                       %TrimR( PxOutFil_q.ObjLib )              +
                       ' has been created.'
                     );

          Else;
            SndCmpMsg( 'User auditing information '             +
                       %TrimR( PxOutFil_q.ObjNam )              +
                       ' in '                                   +
                       %TrimR( PxOutFil_q.ObjLib )              +
                       ' has been updated.'
                     );
          EndIf;

        EndSr;

        BegSr  *InzSr;

          Select;
          When  PxAudVal.NbrAud = 1  And  PxAudVal.AudVal(1) = '*ALL';
            RefAudLvl = *All'Y';

          When  PxAudVal.NbrAud = 1  And  PxAudVal.AudVal(1) = '*NONE';
            RefAudLvl = *Blanks;

          When  PxAudVal.NbrAud = 1  And  PxAudVal.AudVal(1) = '*ANY';
            RefAudLvl = '*ANY';

          Other;
            ExSr  LodRefAud;
          EndSl;

          SysDts = %Timestamp();

          HdrRcd.WrkUsr = PxUsrPrf;
          HdrRcd.PosUsr = *Blanks;

          WrkUsr = HdrRcd.WrkUsr;

        EndSr;

        BegSr  LodRefAud;

          RefAudLvl.AutFail   = ChkAudVal( '*AUTFAIL'  : PxAudVal );
          RefAudLvl.Cmd       = ChkAudVal( '*CMD'      : PxAudVal );
          RefAudLvl.Create    = ChkAudVal( '*CREATE'   : PxAudVal );
          RefAudLvl.Delete    = ChkAudVal( '*DELETE'   : PxAudVal );
          RefAudLvl.JobBas    = ChkAudVal( '*JOBBAS'   : PxAudVal );
          RefAudLvl.JobChgUsr = ChkAudVal( '*JOBCHGUSR': PxAudVal );
          RefAudLvl.JobDta    = ChkAudVal( '*JOBDTA'   : PxAudVal );
          RefAudLvl.NetBas    = ChkAudVal( '*NETBAS'   : PxAudVal );
          RefAudLvl.NetClu    = ChkAudVal( '*NETCLU'   : PxAudVal );
          RefAudLvl.NetCmn    = ChkAudVal( '*NETCMN'   : PxAudVal );
          RefAudLvl.NetFail   = ChkAudVal( '*NETFAIL'  : PxAudVal );
          RefAudLvl.NetSck    = ChkAudVal( '*NETSCK'   : PxAudVal );
          RefAudLvl.ObjMgt    = ChkAudVal( '*OBJMGT'   : PxAudVal );
          RefAudLvl.OfcSrv    = ChkAudVal( '*OFCSRV'   : PxAudVal );
          RefAudLvl.Optical   = ChkAudVal( '*OPTICAL'  : PxAudVal );
          RefAudLvl.PgmAdp    = ChkAudVal( '*PGMADP'   : PxAudVal );
          RefAudLvl.PgmFail   = ChkAudVal( '*PGMFAIL'  : PxAudVal );
          RefAudLvl.PrtDta    = ChkAudVal( '*PRTDTA'   : PxAudVal );
          RefAudLvl.SecCfg    = ChkAudVal( '*SECCFG'   : PxAudVal );
          RefAudLvl.SecDirSrv = ChkAudVal( '*SECDIRSRV': PxAudVal );
          RefAudLvl.SecIpc    = ChkAudVal( '*SECIPC'   : PxAudVal );
          RefAudLvl.SecNas    = ChkAudVal( '*SECNAS'   : PxAudVal );
          RefAudLvl.SecRun    = ChkAudVal( '*SECRUN'   : PxAudVal );
          RefAudLvl.SecSckD   = ChkAudVal( '*SECSCKD'  : PxAudVal );
          RefAudLvl.SecVfy    = ChkAudVal( '*SECVFY'   : PxAudVal );
          RefAudLvl.SecVldL   = ChkAudVal( '*SECVLDL'  : PxAudVal );
          RefAudLvl.SavRst    = ChkAudVal( '*SAVRST'   : PxAudVal );
          RefAudLvl.Security  = ChkAudVal( '*SECURITY' : PxAudVal );
          RefAudLvl.Service   = ChkAudVal( '*SERVICE'  : PxAudVal );
          RefAudLvl.SplfDta   = ChkAudVal( '*SPLFDTA'  : PxAudVal );
          RefAudLvl.SysMgt    = ChkAudVal( '*SYSMGT'   : PxAudVal );

        EndSr;

      /End-Free

     **-- Check audit value:
     P ChkAudVal       B
     D                 Pi             1a
     D  PxChkAut                     10a   Value
     D  PxAudVal                           Value  LikeDs( AudVal )

      /Free

        If  %LookUp( PxChkAut: PxAudVal.AudVal: 1: PxAudVal.NbrAud ) > *Zero;
          Return  'Y';

        Else;
          Return  'N';
        EndIf;

      /End-Free

     P ChkAudVal       E
     **-- Verify user audit level:
     P VfyUsrAud       B
     D                 Pi              n
     D  PxRefAud                           Value  LikeDs( AudLvl )
     D  PxUsrAud                           Value  LikeDs( AudLvl )

      /Free

        Select;
        When  PxRefAud = '*ANY'  And  %Scan( 'Y': PxUsrAud ) > *Zero;
          Return  *On;

        When  CmpUsrAud( PxRefAud: PxUsrAud ) = *On;
          Return  *On;

        Other;
          Return  *Off;
        EndSl;

      /End-Free

     P VfyUsrAud       E
     **-- Compare user audit level:
     P CmpUsrAud       B
     D                 Pi              n
     D  PxRefAud                           Value  LikeDs( AudLvl )
     D  PxUsrAud                           Value  LikeDs( AudLvl )

     **-- Local variables:
     D Idx             s             10i 0

      /Free

        For  Idx = 1  To  %Elem( PxRefAud.AudFlg );

          If  PxRefAud.AudFlg(Idx) = 'Y'  And  PxUsrAud.AudFlg(Idx) = 'N';
            Return  *Off;
          EndIf;
        EndFor;

        Return  *On;

      /End-Free

     P CmpUsrAud       E
     **-- Get user audit values:
     P GetUsrAud       B
     D                 Pi                  LikeDs( AudLvl )
     D  PxUsrPrf                     10a   Value

      /Free

        RtvUsrInf( USRI0300
                 : %Size( USRI0300 )
                 : 'USRI0300'
                 : PxUsrPrf
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blanks;

        Else;
          Return  USRI0300.UsrAudVal;
        EndIf;

      /End-Free

     P GetUsrAud       E
     **-- Get user class:
     P GetUsrCls       B                   Export
     D                 Pi            10a
     D  PxUsrPrf                     10a   Value

     **-- User profile information:
     D USRI0200        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  UsrPrf                       10a
     D  UsrCls                       10a
     D  SpcAut                       15a   Overlay( USRI0200: 29 )
     D   AllObj                       1a   Overlay( SpcAut: 1 )
     D   SecAdm                       1a   Overlay( SpcAut: *Next )
     D   JobCtl                       1a   Overlay( SpcAut: *Next )
     D   SplCtl                       1a   Overlay( SpcAut: *Next )
     D   SavSys                       1a   Overlay( SpcAut: *Next )
     D   Service                      1a   Overlay( SpcAut: *Next )
     D   Audit                        1a   Overlay( SpcAut: *Next )
     D   IoSysCfg                     1a   Overlay( SpcAut: *Next )

      /Free

        RtvUsrInf( USRI0200
                 : %Size( USRI0200 )
                 : 'USRI0200'
                 : PxUsrPrf
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blanks;

        Else;
          Return  USRI0200.UsrCls;
        EndIf;

      /End-Free

     P GetUsrCls       E
     **-- Get group profile:
     P GetGrpPrf       B                   Export
     D                 Pi            10a
     D  PxUsrPrf                     10a   Value

     **-- User profile information:
     D USRI0200        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  UsrPrf                       10a
     D  UsrCls                       10a
     D  SpcAut                       15a   Overlay( USRI0200: 29 )
     D   AllObj                       1a   Overlay( SpcAut: 1 )
     D   SecAdm                       1a   Overlay( SpcAut: *Next )
     D   JobCtl                       1a   Overlay( SpcAut: *Next )
     D   SplCtl                       1a   Overlay( SpcAut: *Next )
     D   SavSys                       1a   Overlay( SpcAut: *Next )
     D   Service                      1a   Overlay( SpcAut: *Next )
     D   Audit                        1a   Overlay( SpcAut: *Next )
     D   IoSysCfg                     1a   Overlay( SpcAut: *Next )
     D  GrpPrf                       10a

      /Free

        RtvUsrInf( USRI0200
                 : %Size( USRI0200 )
                 : 'USRI0200'
                 : PxUsrPrf
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blanks;

        Else;
          Return  USRI0200.GrpPrf;
        EndIf;

      /End-Free

     P GetGrpPrf       E
     **-- Get job type:
     P GetJobTyp       B                   Export
     D                 Pi             1a

     D JOBI0400        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  JobNam                       10a
     D  UsrNam                       10a
     D  JobNbr                        6a
     D  JobIntId                     16a
     D  JobSts                       10a
     D  JobTyp                        1a
     D  JobSubTyp                     1a

      /Free

        RtvJobInf( JOBI0400
                 : %Size( JOBI0400 )
                 : 'JOBI0400'
                 : '*'
                 : *Blank
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blank;

        Else;
          Return  JOBI0400.JobTyp;
        EndIf;

      /End-Free

     P GetJobTyp       E
     **-- Check object existence:
     P ChkObj          B
     D                 Pi              n
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const

     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     **-- Object information:
     D OBJD0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a

      /Free

         RtvObjD( OBJD0100
                : %Size( OBJD0100 )
                : 'OBJD0100'
                : PxObjNam_q
                : PxObjTyp
                : ERRC0100
                );

         If  ERRC0100.BytAvl > *Zero;
           Return  *Off;

         Else;
           Return  *On;
         EndIf;

      /End-Free

     P ChkObj          E
     **-- Get object library:
     P GetObjAtr       B
     D                 Pi            10a
     D  PxObjNam_q                         LikeDs( ObjNam_q )
     D  PxObjTyp                     10a   Const

     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     **-- Object information:
     D OBJD0200        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a
     D  ObjLibRtn                    10a
     D  ObjASP                       10i 0
     D  ObjOwn                       10a
     D  ObjDmn                        2a
     D  ObjExtAtr                    10a   Overlay( OBJD0200: 91 )

      /Free

        RtvObjD( OBJD0200
               : %Size( OBJD0200 )
               : 'OBJD0200'
               : PxObjNam_q
               : PxObjTyp
               : ERRC0100
               );

        If  ERRC0100.BytAvl > *Zero;
          Return  *LoVal;

        Else;
          Return  OBJD0200.ObjExtAtr;
        EndIf;

      /End-Free

     P GetObjAtr       E
     **-- Get object library:
     P GetObjLib       B
     D                 Pi            10a
     D  PxObjNam_q                         LikeDs( ObjNam_q )
     D  PxObjTyp                     10a   Const

     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     **-- Object information:
     D OBJD0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a
     D  ObjLibRtn                    10a
     D  ObjASP                       10i 0
     D  ObjOwn                       10a
     D  ObjDmn                        2a

      /Free

        RtvObjD( OBJD0100
               : %Size( OBJD0100 )
               : 'OBJD0100'
               : PxObjNam_q
               : PxObjTyp
               : ERRC0100
               );

        If  ERRC0100.BytAvl > *Zero;
          Return  GetCurLib();

        Else;
          Return  OBJD0100.ObjLibRtn;
        EndIf;

      /End-Free

     P GetObjLib       E
     **-- Get current library:
     P GetCurLib       B
     D                 Pi            10a

     **-- Thread library information:
     D JOBI0700        Ds         65535    Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  JobNam                       10a
     D  UsrNam                       10a
     D  JobNbr                        6a
     D  IntJobId                     16a
     D  JobSts                       10a
     D  JobTyp                        1a
     D  JobSubTyp                     1a
     D  Rsv                           2a
     D  NbrSysLib                    10i 0
     D  NbrPrdLib                    10i 0
     D  NbrCurLib                    10i 0
     D  NbrUsrLib                    10i 0
     D  LibAry                       11a   Dim( 512 )
     **-- Local variables:
     D LibIdx          s             10i 0

      /Free

        RtvJobInf( JOBI0700
                 : %Size( JOBI0700 )
                 : 'JOBI0700'
                 : '*'
                 : *Blanks
                 : ERRC0100
                 );

        Select;
        When  ERRC0100.BytAvl > *Zero;
          Return  'QGPL';

        When  JOBI0700.NbrCurLib = *Zero;
          Return  'QGPL';

        Other;
          LibIdx = JOBI0700.NbrSysLib +
                   JOBI0700.NbrPrdLib +
                   JOBI0700.NbrCurLib;

          Return  JOBI0700.LibAry(LibIdx);
        EndSl;

      /End-Free

     P GetCurLib       E
     **-- Get net attribute:
     P GetNetAtr       B
     D                 Pi          4096a   Varying
     D  PxNetAtr                     10a   Const

     **-- Local variables:
     D Idx             s             10i 0
     D NetAtr          s           4096a   Varying
     **
     D ApiPrm          Ds                  Qualified
     D  RtnAtrLen                    10i 0
     D  NetAtrNbr                    10i 0 Inz( %Elem( ApiPrm.NetAtr ))
     D  NetAtr                       10a   Dim( 1 )
     **
     D RtnVar          Ds                  Qualified
     D  RtnVarNbr                    10i 0
     D  RtnVarOfs                    10i 0 Dim( %Elem( ApiPrm.NetAtr ))
     D  RtnVarDta                  4096a

     D RtnAtr          Ds                  Qualified  Based( RtnValPtr )
     D  AtrNam                       10a
     D  DtaTyp                        1a
     D  InfSts                        1a
     D  AtrLen                       10i 0
     D  Atr                        4096a
     D  AtrInt                       10i 0 Overlay( Atr )

      /Free

        ApiPrm.RtnAtrLen = %Elem( ApiPrm.NetAtr ) * 24 + %Size( NetAtr ) + 4;
        ApiPrm.NetAtr(1) = PxNetAtr;

        RtvNetAtr( RtnVar
                 : ApiPrm.RtnAtrLen
                 : ApiPrm.NetAtrNbr
                 : ApiPrm.NetAtr
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          NetAtr = NULL;

        Else;
          For  Idx = 1  to RtnVar.RtnVarNbr;

            RtnValPtr = %Addr( RtnVar ) + RtnVar.RtnVarOfs(Idx);

            If  RtnAtr.AtrNam = PxNetAtr;

              Select;
              When  RtnAtr.DtaTyp = 'C';
                NetAtr = %Subst( RtnAtr.Atr: 1: RtnAtr.AtrLen );

              When  RtnAtr.DtaTyp = 'B';
                NetAtr = %Char( RtnAtr.AtrInt );

              Other;
                NetAtr = NULL;
              EndSl;
            EndIf;

          EndFor;
        EndIf;

        Return  NetAtr;

      /End-Free

     P GetNetAtr       E
     **-- Verify format level:
     P VfyFmtLvl       B
     D                 Pi              n
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxFmtLvlId                   13a   Const

     **-- Local constants:
     D LCL_SYS         c                   '*LCL'
     D EXT_FMT         c                   '*EXT'
     D NO_OVR_PRC      c                   '0'
     **-- Local variables:
     D RtnInd          s               n   Inz( *On )
     D FilNamRtn_q     s             20a
     **-- FILD0200 format:
     D Qdb_Qddfmt      Ds          1024    Qualified
     D  Qddbyrtn                     10i 0
     D  Qddbyava                     10i 0
     D  Reserved_62                  24a
     D  Qddfmtf                       1a
     D  Qddfxlto                     10i 0
     D  Qddfrcao                     10i 0
     D  Qddfdico                     10i 0
     D  Qddfrcid                      5i 0
     D  Qddfsrcd                      5i 0
     D  Qddfrtcd                      5i 0
     D  Qddfrlcd                      5i 0
     D  Reserved_64                   7a
     D  Qddftflgs                     1a
     D  Qddflgs                       1a
     D  Reserved_67                   4a
     D  Qddfrlen                     10i 0
     D  Qddfname                     10a
     D  Qddfseq                      13a
     D  Qddftext                     50a
     D  Qddffldnum                    5i 0
     D  Qddf_...
     D  Identity_Off                 10i 0

      /Free

        If  GetObjAtr( PxFilNam_q: '*FILE' ) <> 'PF';
          RtnInd = *Off;

        Else;
          RtvDbfDsc( Qdb_Qddfmt
                   : %Size( Qdb_Qddfmt )
                   : FilNamRtn_q
                   : 'FILD0200'
                   : PxFilNam_q
                   : '*FIRST'
                   : NO_OVR_PRC
                   : LCL_SYS
                   : EXT_FMT
                   : ERRC0100
                   );

          Select;
          When  ERRC0100.BytAvl > *Zero;
            RtnInd = *Off;

          When  Qdb_Qddfmt.Qddfseq <> PxFmtLvlId;
            RtnInd = *Off;
          EndSl;
        EndIf;

        Return  RtnInd;

      /End-Free

     P VfyFmtLvl       E
     **-- Clear physical file member:
     P ClrPfm          B
     D                 Pi            10i 0
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxMbrNam                     10a   Const  Varying  Options( *Trim )

     **-- Local variables:
     D FilNam_q        s             21a   Varying

      /Free

        FilNam_q = %TrimR( PxOutFil_q.ObjLib ) + '/' +
                   %TrimR( PxOutFil_q.ObjNam );

        PrcCmd( 'CLRPFM FILE(' + FilNam_q + ') MBR(' + PxMbrNam + ')' );

        Return  *Zero;

      /End-Free

     P ClrPfm          E
     **-- Process command:
     P PrcCmd          B
     D                 Pi            10i 0
     D  PxCmdStr                   4096a   Const  Varying

     **-- Option control block:
     D CPOP0100        Ds                  Qualified
     D  TypPrc                       10i 0 Inz( 2 )
     D  DBCS                          1a   Inz( '0' )
     D  PmtAct                        1a   Inz( '2' )
     D  CmdStx                        1a   Inz( '0' )
     D  MsgRtvKey                     4a   Inz( *Allx'00' )
     D  CmdCcsId                     10i 0 Inz( JOB_CCSID )
     D  Rsv                           5a   Inz( *Allx'00' )
     **
     D ChgCmd          s          32767a
     D ChgCmdAvl       s             10i 0
     **-- API error data structure:
     D ERRC0100_I      Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0

      /Free

        PrcCmds( PxCmdStr
               : %Len( PxCmdStr )
               : CPOP0100
               : %Size( CPOP0100 )
               : 'CPOP0100'
               : ChgCmd
               : %Size( ChgCmd )
               : ChgCmdAvl
               : ERRC0100
               );

        If  ERRC0100.BytAvl > *Zero;
          MovPgmMsg( *Blanks
                   : '*DIAG'
                   : 1
                   : '*PGMBDY'
                   : 1
                   : ERRC0100_I
                   );

          If  ERRC0100.BytAvl < OFS_MSGDTA;
            ERRC0100.BytAvl = OFS_MSGDTA;
          EndIf;

          SndEscMsg( ERRC0100.MsgId
                   : 'QCPFMSG'
                   : %Subst( ERRC0100.MsgDta: 1: ERRC0100.BytAvl - OFS_MSGDTA )
                   );

          Return  -1;
        Else;

          Return  *Zero;
        EndIf;

      /End-Free

     P PrcCmd          E
     **-- Check for an error in processed SQL statement:
     P Check_error     B
     D                 Pi
     D  rc                           10i 0 Value
     D  env                                Like( SQLHENV )   Value
     D  conn                               Like( SQLHDBC )   Value
     D  stmt                               Like( SQLHSTMT )  Value
     D  function                     50a   Varying  Const

     **-- Local variables:
     D sqlstate        s              6a
     D sqlcode         s                   Like( SQLINTEGER )
     D msgbytes        s                   Like( SQLSMALLINT )
     D errmsg          s            513a
     D rtnmsg          s           1024a   Varying

      /Free

        If  rc = SQL_NO_DATA_FOUND  Or  rc = SQL_SUCCESS;

          Return;
        EndIf;

        SQLError( env
                : conn
                : stmt
                : sqlstate
                : sqlcode
                : errmsg
                : %Size( errmsg )
                : msgbytes
                );

        If  rc < SQL_SUCCESS;

          If  msgbytes > *Zero;
            SndDiagMsg( 'CPF9897': %Subst( errmsg: 1: msgbytes ));
          EndIf;

          rtnmsg = Function     + ' failed.  '        +
                   'RC= '       + %Char( rc )         + ', '  +
                   'SQLCODE= '  + %Char( sqlcode )    + ', '  +
                   'SQLSTATE= ' + %Trim( sqlstate )   + '.';

          SndEscMsg( 'CPF9897': 'QCPFMSG': rtnmsg );

        Else;
          If  msgbytes > *Zero;
            SndDiagMsg( 'CPF9897': %Subst( errmsg: 1: msgbytes ));
          EndIf;

          rtnmsg = Function     + ' succeeded.  '     +
                   'RC= '       + %Char( rc )         + ', '  +
                   'SQLCODE= '  + %Char( sqlcode )    + ', '  +
                   'SQLSTATE= ' + %Trim( sqlstate )   + '.';

          SndDiagMsg( 'CPF9897': rtnmsg );
        EndIf;

        Return;

      /End-Free

     P Check_error     E
     **-- Send status message:
     P SndStsMsg       B                   Export
     D                 Pi            10i 0
     D  PxMsgDta                   1024a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( 'CPF9897'
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*STATUS'
                 : '*EXT'
                 : 0
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndStsMsg       E
     **-- Send completion message:
     P SndCmpMsg       B                   Export
     D                 Pi            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( 'CPF9897'
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*COMP'
                 : '*CTLBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return  0;

        EndIf;

      /End-Free

     P SndCmpMsg       E
     **-- Send diagnostic message:
     P SndDiagMsg      B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*DIAG'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndDiagMsg      E
     **-- Send escape message:
     P SndEscMsg       B                   Export
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : PxMsgF + '*LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*CTLBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
     **-- Cleanup resources:
     P Cleanup         B
     D                 Pi

      /Free

        CloApp( UIM.AppHdl: CLO_NORM: ERRC0100 );

        If  stmt <> SQL_NULL_HSTMT;
          SQLFreeStmt( stmt :SQL_DROP );

          stmt = SQL_NULL_HSTMT;
        EndIf;

        If  conn <> SQL_NULL_HDBC;
          SQLDisconnect( conn );
          SQLFreeConnect( conn );

          conn = SQL_NULL_HDBC;
        EndIf;

        If  env <> SQL_NULL_HENV;
          SQLFreeEnv( env );

          env = SQL_NULL_HENV;
        EndIf;

      /End-Free

     P Cleanup         E
