/*-------------------------------------------------------------------*/
/*                                                                   */
/*  Compile options:                                                 */
/*                                                                   */
/*    CrtCmd Cmd( UPDUSRAUD )                                        */
/*           Pgm( SEC102 )                                           */
/*           SrcMbr( SEC102X )                                       */
/*           HlpPnlGrp( SEC102H )                                    */
/*           HlpId( *CMD )                                           */
/*           PmtOvrPgm( SEC102O )                                    */
/*           Aut( *EXCLUDE )                                         */
/*                                                                   */
/*-------------------------------------------------------------------*/
          Cmd      Prompt( 'Update User Auditing' )        +
                   AlwLmtUsr( *NO )                        +
                   HlpId( *CMD )                           +
                   HlpPnlGrp( SEC102H )                    +
                   Text( 'Update User Auditing')           +
                   Aut( *EXCLUDE )


          Parm     USRPRF         *Sname       10          +
                   Min( 1 )                                +
                   Expr( *YES )                            +
                   Keyparm( *YES )                         +
                   Vary( *YES *INT2 )                      +
                   Prompt( 'User profile' )

          Parm     OBJAUD         *Char        10          +
                   Rstd( *YES )                            +
                   Dft( *SAME )                            +
                   SpcVal(( *SAME   )                      +
                          ( *NONE   )                      +
                          ( *CHANGE )                      +
                          ( *ALL    ))                     +
                   Expr( *YES )                            +
                   Vary( *YES *INT2 )                      +
                   Prompt( 'Object auditing value' )

          Parm     AUDLVL         *Char        10          +
                   Rstd( *YES )                            +
                   Dft( *SAME )                            +
                   SpcVal(( *AUTFAIL  )                    +
                          ( *CMD      )                    +
                          ( *CREATE   )                    +
                          ( *DELETE   )                    +
                          ( *JOBBAS   )                    +
                          ( *JOBCHGUSR)                    +
                          ( *JOBDTA   )                    +
                          ( *NETBAS   )                    +
                          ( *NETCLU   )                    +
                          ( *NETCMN   )                    +
                          ( *NETFAIL  )                    +
                          ( *NETSCK   )                    +
                          ( *OBJMGT   )                    +
                          ( *OFCSRV   )                    +
                          ( *OPTICAL  )                    +
                          ( *PGMADP   )                    +
                          ( *PGMFAIL  )                    +
                          ( *PRTDTA   )                    +
                          ( *SECCFG   )                    +
                          ( *SECDIRSRV)                    +
                          ( *SECIPC   )                    +
                          ( *SECNAS   )                    +
                          ( *SECRUN   )                    +
                          ( *SECSCKD  )                    +
                          ( *SECVFY   )                    +
                          ( *SECVLDL  )                    +
                          ( *SAVRST   )                    +
                          ( *SECURITY )                    +
                          ( *SERVICE  )                    +
                          ( *SPLFDTA  )                    +
                          ( *SYSMGT   ))                   +
                   SngVal(( *SAME ) ( *NONE ))             +
                   Max( 31 )                               +
                   Expr( *YES )                            +
                   Vary( *YES *INT2 )                      +
                   Prompt( 'User action auditing' )

