/*-------------------------------------------------------------------*/
/*                                                                   */
/*  Program . . :  SEC100T                                           */
/*  Description :  Verify Query Output File - Test                   */
/*  Author  . . :  Carsten Flensburg                                 */
/*                                                                   */
/*                                                                   */
/*  Program function:  Demonstrates the use of the Verify Query      */
/*                     File (VFYQRYOUTF) command.                    */
/*                                                                   */
/*                     When calling this program you must specify    */
/*                     a 10-byte parameter, defining the library     */
/*                     for which to run the VRYQRYOUTF command       */
/*                     against all physical files.                   */
/*                                                                   */
/*                                                                   */
/*  Compile options:                                                 */
/*    CrtClPgm    Pgm( SEC100T )                                     */
/*                SrcFile( QCLSRC )                                  */
/*                SrcMbr( *PGM )                                     */
/*                                                                   */
/*-------------------------------------------------------------------*/
     Pgm      ( &FilLib )

/*-- Variable declarations:  --*/
     Dcl        &FilLib      *Char    10
     Dcl        &UsrPrf      *Char    10
     Dcl        &QryFind     *Char     1

     DclF       QAFDBASI


/*-- Monitor exception messages:  --*/
     MonMsg     CPF0000      *N        GoTo Error


     RtvJobA    User( &UsrPrf )

     DspFd      File( &FilLib/*ALL )                       +
                Type( *BASATR )                            +
                FileAtr( *PF )                             +
                OutPut( *OUTFILE )                         +
                OutFile( QTEMP/QAFDBASI )

     OvrDbf     QAFDBASI     ToFile( QTEMP/QAFDBASI )

RcvF:
     RcvF
     MonMsg     CPF0864      *N      GoTo EoF

     VfyQryOutF File( &ATLIB/&ATFILE )    QryFind( &QryFind )

     If       ( &QryFind = 'Y' )     Do
                                                           +
     SndPgmMsg  MsgId( CPF9897 )                           +
                MsgF( QCPFMSG )                            +
                MsgDta( 'File'       *Bcat &ATFILE *Bcat   +
                        'in library' *Bcat &ATLIB  *Bcat   +
                        'is a query output file.' )        +
                ToUsr( &UsrPrf )                           +
                MsgType( *INFO )
     EndDo

     GoTo       RcvF

EoF:
     DltOvr     QAFDBASI

 Return:
     Return

/*-- Error handling:  --*/
 Error:
     Call        QMHMOVPM    ( '    '                 +
                               '*DIAG'                +
                               x'00000001'            +
                               '*PGMBDY'              +
                               x'00000001'            +
                               x'0000000800000000'    +
                             )

     Call        QMHRSNEM    ( '    '                 +
                               x'0000000800000000'    +
                             )
 EndPgm:
     EndPgm
