     **
     **  Program . . : SEC100
     **  Description : Verify query output file
     **  Author  . . : Carsten Flensburg
     **
     **
     **
     **  Compile options:
     **    CrtRpgMod   Module( SEC100 )
     **                DbgView( *LIST )
     **
     **    CrtPgm      Pgm( SEC100 )
     **                Module( SEC100 )
     **                ActGrp( *NEW )
     **
     **-- Header specifications:  --------------------------------------------**
     H Option( *SrcStmt )  BndDir( 'QC2LE' )

     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     D  MsgId                         7a
     D                                1a
     D  MsgDta                      128a

     **-- Global constants:
     D OFS_MSGDTA      c                   16
     D NO_OVR_PRC      c                   '0'
     D SYS_LCL         c                   '*LCL'
     D FMT_EXT         c                   '*EXT'
     **
     D FIL_PHY         c                   0
     D FIL_DTA         c                   0
     D PGM_DSC         c                   7
     D TYPE_OF_FILE    c                   2
     D FILE_TYPE       c                   4
     D SQL_TBL         c                   4

     **-- QDBRTVFD API parameter:
     D FilRtn_q        Ds                  Qualified
     D  FilNam                       10a
     D  LibNam                       10a
     **-- Global variables:
     D ApiRcvSiz       s             10u 0 Inz( *Zero )
     D QryOutFil       s              1a

     **-- FILD0100 formats:
     D Qdb_Qdbfh       Ds                  Based( pQdb_Qdbfh )  Qualified
     D  Qdbfyret                     10i 0
     D  Qdbfyavl                     10i 0
     D  Qdbfhflg                      2a
     D*  Reserved_1    :2
     D*  Qdbfhfpl      :1
     D*  Reserved_2    :1
     D*  Qdbfhfsu      :1
     D*  Reserved_3    :1
     D*  Qdbfhfky      :1
     D*  Reserved_4    :1
     D*  Qdbfhflc      :1
     D*  Qdbfkfso      :1
     D*  Reserved_5    :4
     D*  Qdbfigcd      :1
     D*  Qdbfigcl      :1
     D  Reserved_7                    4a
     D  Qdbflbnum                     5i 0
     D  Qdbfkdat                     14a
     D  Qdbfknum                      5i 0 Overlay( Qdbfkdat: 1 )
     D  Qdbfkmxl                      5i 0 Overlay( Qdbfkdat: *Next )
     D  Qdbfkflg                      1a   Overlay( Qdbfkdat: *Next )
     D*  Reserved_8    :1
     D*  Qdbfkfcs      :1
     D*  Reserved_9    :4
     D*  Qdbfkfrc      :1
     D*  Qdbfkflt      :1
     D  Qdbfkfdm                      1a   Overlay( Qdbfkdat: *Next )
     D  Reserved_10                   8a   Overlay( Qdbfkdat: *Next )
     D  Qdbfhaut                     10a
     D  Qdbfhupl                      1a
     D  Qdbfhmxm                      5i 0
     D  Qdbfwtfi                      5i 0
     D  Qdbfhfrt                      5i 0
     D  Qdbfhmnum                     5i 0
     D  Reserved_11                   9a
     D  Qdbfbrwt                      5i 0
     D  Qaaf                          1a
     D*  Reserved_12   :7
     D*  Qdbfpgmd      :1
     D  Qdbffmtnum                    5i 0
     D  Qdbfhfl2                      2a
     D*  Qdbfjnap      :1
     D*  Reserved_13   :1
     D*  Qdbfrdcp      :1
     D*  Qdbfwtcp      :1
     D*  Qdbfupcp      :1
     D*  Qdbfdlcp      :1
     D*  Reserved_14   :9
     D*  Qdbfkfnd      :1
     D  Qdbfvrm                       5i 0
     D  Qaaf2                         2a
     D*  Qdbfhmcs      :1
     D*  Reserved_15   :1
     D*  Qdbfknll      :1
     D*  Qdbf_nfld     :1
     D*  Qdbfvfld      :1
     D*  Qdbftfld      :1
     D*  Qdbfgrph      :1
     D*  Qdbfpkey      :1
     D*  Qdbfunqc      :1
     D*  Reserved_118  :2
     D*  Qdbfapsz      :1
     D*  Qdbfdisf      :1
     D*  Reserved_68   :1
     D*  Reserved_69   :1
     D*  Reserved_70   :1
     D  Qdbfhcrt                     13a
     D  Qdbfhtx                      52a
     D   Reserved_18                  2a   Overlay( Qdbfhtx: 1 )
     D   Qdbfhtxt                    50a   Overlay( Qdbfhtx: *Next )
     D  Reserved_19                  13a
     D  Qdbfsrc                      30a
     D   Qdbfsrcf                    10a   Overlay( Qdbfsrc: 1 )
     D   Qdbfsrcm                    10a   Overlay( Qdbfsrc: *Next )
     D   Qdbfsrcl                    10a   Overlay( Qdbfsrc: *Next )
     D  Qdbfkrcv                      1a
     D  Reserved_20                  23a
     D  Qdbftcid                      5i 0
     D  Qdbfasp                       2a
     D  Qdbfnbit                      1a
     D*  Qdbfhudt      :1
     D*  Qdbfhlob      :1
     D*  Qdbfhdtl      :1
     D*  Qdbfhudf      :1
     D*  Qdbfhlon      :1
     D*  Qdbfhlop      :1
     D*  Qdbfhdll      :1
     D*  Reserved_21   :1
     D  Qdbfmxfnum                    5i 0
     D  Reserved_22                  76a
     D  Qdbfodic                     10i 0
     D  Reserved_23                  14a
     D  Qdbffigl                      5i 0
     D  Qdbfmxrl                      5i 0
     D  Reserved_24                   8a
     D  Qdbfgkct                      5i 0
     D  Qdbfos                       10i 0
     D  Reserved_25                   8a
     D  Qdbfocs                      10i 0
     D  Reserved_26                   4a
     D  Qdbfpact                      2a
     D  Qdbfhrls                      6a
     D  Reserved_27                  20a
     D  Qdbpfof                      10i 0
     D  Qdblfof                      10i 0
     D  Qdbfssfp                      6a
     D   Qdbfnlsb                     1a   Overlay( Qdbfssfp: 1 )
     D*   Qdbfsscs     :3
     D*   Reserved_103 :5
     D   Qdbflang                     3a   Overlay( Qdbfssfp: *Next )
     D   Qdbfcnty                     2a   Overlay( Qdbfssfp: *Next )
     D  Qdbfjorn                     10i 0
     D  Qdbfevid                     10i 0
     D  Reserved_28                  14a
     **
     D Qdb_Qdbfb       Ds                  Qualified  Based( pQdb_Qdbfb )
     D  Reserved_48                  48a
     D  Qdbfbf                       10a
     D  Qdbfbfl                      10a
     D  Qdbft                        10a
     D  Reserved_49                  37a
     D  Qdbfbgky                      5i 0
     D  Reserved_50                   2a
     D  Qdbfblky                      5i 0
     D  Reserved_51                   2a
     D  Qdbffogl                      5i 0
     D  Reserved_52                   3a
     D  Qdbfsoon                      5i 0
     D  Qdbfsoof                     10i 0
     D  Qdbfksof                     10i 0
     D  Qdbfkyct                      5i 0
     D  Qdbfgenf                      5i 0
     D  Qdbfodis                     10i 0
     D  Reserved_53                  14a
     **
     D Qdb_Qdbfphys    Ds                  Qualified  Based( pQdb_Qdbfphys )
     D  Qdbfpalc                      2a
     D  Qdbfcmps                      1a
     D  Qdbfoff_sqpt                 10i 0
     D  Reserved_29                   4a
     D  Qdbfprnum                    10i 0
     D  Qdbfpri                       5i 0
     D  Qdbfprinum                    5i 0
     D  Qdbforid                     10i 0
     D  Qflags                        1a
     D*  Qdbfrdel      :1
     D*  Reserved_30   :3
     D*  Qdbfsqlt      :1
     D*  Qdbfmqt       :1
     D*  Qdbfsqpt      :1
     D*  Reserved_31   :1
     D  Qdbfotrg                     10i 0
     D  Qdbftrgn                      5i 0
     D  Qdbfofcs                     10i 0
     D  Qdbfcstn                     10i 0
     D  Qdbfodl                      10i 0
     D  Qdbfovw_mqt                  10i 0
     D  Reserved_32                   2a

     **-- Retrieve database file description:
     D RtvDbfDsc       Pr                  ExtPgm( 'QDBRTVFD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FilRtn_q                     20a
     D  FmtNam                        8a   Const
     D  FilNamQ                      20a   Const
     D  RcdFmtNam                    10a   Const
     D  OvrPrc                        1a   Const
     D  System                       10a   Const
     D  FmtTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )

     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      128a   Const
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve object description:
     D RtvObjD         Pr                  ExtPgm( 'QUSROBJD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  ObjNamQ                      20a   Const
     D  ObjTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Test bit in string:
     D tstbts          Pr            10i 0 ExtProc( 'tstbts' )
     D  String                         *   Value
     D  BitOfs                       10u 0 Value

     **-- Get object source member:
     D GetObjSrcM      Pr            10a
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const
     **-- Get object creator:
     D GetObjCrt       Pr            10a
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const
     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying

     **-- Program entry:
     D ObjNam_q        Ds
     D  ObjNam                       10a
     D  ObjLib                       10a
     **
     D SEC100          Pr
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxQryOutFil                   1a
     **
     D SEC100          Pi
     D  PxFilNam_q                         LikeDs( ObjNam_q )
     D  PxQryOutFil                   1a

      /Free

        ApiRcvSiz  = 65535;

        pQdb_Qdbfh = %Alloc( ApiRcvSiz );
        Qdb_Qdbfh.Qdbfyavl = *Zero;

        DoU  Qdb_Qdbfh.Qdbfyavl <= ApiRcvSiz;

          If  Qdb_Qdbfh.Qdbfyavl > ApiRcvSiz;
            ApiRcvSiz = Qdb_Qdbfh.Qdbfyavl;

            pQdb_Qdbfh  = %ReAlloc( pQdb_Qdbfh: ApiRcvSiz );
          EndIf;

          RtvDbfDsc( Qdb_Qdbfh
                   : ApiRcvSiz
                   : FilRtn_q
                   : 'FILD0100'
                   : PxFilNam_q
                   : *Blanks
                   : NO_OVR_PRC
                   : SYS_LCL
                   : FMT_EXT
                   : ERRC0100
                   );

          If  ERRC0100.BytAvl > *Zero;
            ExSr  EscApiErr;
          EndIf;
        EndDo;

        ExSr  ChkFilInf;

        *InLr = *On;
        Return;


        BegSr  EscApiErr;

          If  ERRC0100.BytAvl < OFS_MSGDTA;
            ERRC0100.BytAvl = OFS_MSGDTA;
          EndIf;

          SndEscMsg( ERRC0100.MsgId
                   : 'QCPFMSG'
                   : %Subst( ERRC0100.MsgDta: 1: ERRC0100.BytAvl - OFS_MSGDTA )
                   );

        EndSr;

        BegSr  ChkFilInf;

          PxQryOutFil = 'N';

          If  tstbts( %Addr( Qdb_Qdbfh.Qdbfhflg ): TYPE_OF_FILE ) = FIL_PHY;

            If  tstbts( %Addr( Qdb_Qdbfh.Qdbfhflg ): FILE_TYPE ) = FIL_DTA;

              If  tstbts( %Addr( Qdb_Qdbfh.Qaaf ): PGM_DSC ) = *Zero;

                If  Qdb_Qdbfh.Qdbfpact = 'AR';

                  If  Qdb_Qdbfh.Qdbffmtnum = 1;

                    ExSr  ChkObjAtr;
                  EndIf;
                EndIf;
              EndIf;
            EndIf;
          EndIf;

        EndSr;

        BegSr  ChkObjAtr;

          pQdb_Qdbfb = pQdb_Qdbfh + Qdb_Qdbfh.Qdbfos;

          If  Qdb_Qdbfb.Qdbft = PxFilNam_q.ObjNam;

            pQdb_Qdbfphys = pQdb_Qdbfh + Qdb_Qdbfh.Qdbpfof;

            If  tstbts( %Addr( Qdb_Qdbfphys.Qflags ): SQL_TBL ) = *Zero;

              If  GetObjCrt( PxFilNam_q: '*FILE' ) <> '*IBM';

                If  GetObjSrcM( PxFilNam_q: '*FILE' ) = *Blanks;

                  PxQryOutFil = 'Y';
                EndIf;
              EndIf;
            EndIf;
          EndIf;

        EndSr;

      /End-Free

     **-- Get object source member:
     P GetObjSrcM      B
     D                 Pi            10a
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const

     **-- OBJD0200 format:
     D OBJD0200        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a
     D  SrcFil                       20a   Overlay( OBJD0200: 151 )
     D  SrcMbr                       10a   Overlay( OBJD0200: 171 )

      /Free

        RtvObjD( OBJD0200
               : %Size( OBJD0200 )
               : 'OBJD0200'
               : PxObjNam_q
               : PxObjTyp
               : ERRC0100
               );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blanks;

        Else;
          Return  OBJD0200.SrcMbr;
        EndIf;

      /End-Free

     P GetObjSrcM      E
     **-- Get object creator:
     P GetObjCrt       B
     D                 Pi            10a
     D  PxObjNam_q                   20a   Const
     D  PxObjTyp                     10a   Const

     **-- OBJD0300 format:
     D OBJD0300        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjCrt                       10a   Overlay( OBJD0300: 220 )

      /Free

        RtvObjD( OBJD0300
               : %Size( OBJD0300 )
               : 'OBJD0300'
               : PxObjNam_q
               : PxObjTyp
               : ERRC0100
               );

        If  ERRC0100.BytAvl > *Zero;
          Return  *Blanks;

        Else;
          Return  OBJD0300.ObjCrt;
        EndIf;

      /End-Free

     P GetObjCrt       E
     **-- Send escape message:
     P SndEscMsg       B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : PxMsgF + '*LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
