     **
     **  Program . . : CBX3031V
     **  Description : Add Workload Capping Subsystem - VCP
     **  Author  . . : Carsten Flensburg
     **
     **
     **  Program description:
     **    This program checks the existence of the specified objects.
     **
     **
     **  Compile options:
     **    CrtRpgMod Module( CBX3031V )
     **              DbgView( *LIST )
     **
     **    CrtPgm    Pgm( CBX3031V )
     **              Module( CBX3031V )
     **              ActGrp( *CALLER )
     **
     **
     **-- Control specification:  --------------------------------------------**
     H Option( *SrcStmt )

     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     D  ExcpId                        7a
     D                                1a
     D  ExcpDta                     512a
     **-- Global constants:
     D NULL            c                   ''
     D WLC_DTA         c                   'QWTWLCGRP '
     D WLC_LIB         c                   'QSYS      '

     **-- Retrieve object description:
     D RtvObjD         Pr                  ExtPgm( 'QUSROBJD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  ObjNamQ                      20a   Const
     D  ObjTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve workload capping group information:
     D RtvWlgInf       Pr                  ExtPgm( 'QLZRTVWC' )
     D  RcvVar                    65535a   Const  Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  RcvFmtNam                     8a   Const
     D  QryVal                    65535a   Const  Options( *VarSize )
     D  QryFmtNam                     8a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Check user authority to object:
     D ChkUsrAut       Pr                  ExtPgm( 'QSYCUSRA' )
     D  AutInd                        1a
     D  UsrPrf                       10a   Const
     D  ObjNam_q                     20a   Const
     D  ObjTyp                       10a   Const
     D  AutVal                       10a   Const  Dim( 11 )
     D  NbrAut                       10i 0 Const
     D  CalLvl                       10i 0 Const
     D  Error                     32767a         Options( *NoPass: *VarSize )
     **-- Retrieve message description:
     D RtvMsgD         Pr                  ExtPgm( 'QMHRTVM' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                       10a   Const
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      512a   Const  Options( *VarSize )
     D  MsgDtaLen                    10i 0 Const
     D  RplSubVal                    10a   Const
     D  RtnFmtChr                    10a   Const
     D  Error                     32767a          Options( *VarSize )
     D  RtvOpt                       10a   Const  Options( *NoPass )
     D  CvtCcsId                     10i 0 Const  Options( *NoPass )
     D  DtaCcsId                     10i 0 Const  Options( *NoPass )
     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      128a   Const
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                      1024a          Options( *VarSize )

     **-- Check object existence:
     D ChkObj          Pr              n
     D  PxObjNam                     10a   Const
     D  PxLibNam                     10a   Const
     D  PxObjTyp                     10a   Const
     **-- Check object authority:
     D ChkObjAut       Pr              n
     D  PxObjNam                     10a   Const
     D  PxLibNam                     10a   Const
     D  PxObjTyp                     10a   Const
     D  PxChkAut                     10a   Const
     **-- Retrieve message:
     D RtvMsg          Pr          4096a   Varying
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **-- Send diagnostic message:
     D SndDiagMsg      Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying

     **-- Entry parameters:
     D SbsGrp          Ds                  Qualified
     D   NbrElm                       5i 0 Overlay( SbsGrp:  1 )
     D   WlcGrp                      10a   Overlay( SbsGrp:  3 )
     D   SbsNam                      10a   Overlay( SbsGrp: 13 )
     **
     D CBX3031V        Pr
     D  PxSbsGrp                           LikeDs( SbsGrp )
     D  PxCrtDtaAra                   4a
     **
     D CBX3031V        Pi
     D  PxSbsGrp                           LikeDs( SbsGrp )
     D  PxCrtDtaAra                   4a

      /Free

        If  %Scan( '*': PxSbsGrp.SbsNam ) = *Zero  And
            ChkObj( PxSbsGrp.SbsNam: '*LIBL': '*SBSD' ) = *Off;
          SndDiagMsg( 'CPD0006'
                    : '0000' +
                      RtvMsg( 'CPD1407': PxSbsGrp.SbsNam )
                    );

          SndEscMsg( 'CPF0002': '' );
        EndIf;

        If  ChkWlcGrp( PxSbsGrp.WlcGrp ) = *Off;

          SndDiagMsg( 'CPD0006'
                    : '0000' +
                      RtvMsg( 'CPF102A': PxSbsGrp.WlcGrp )
                    );

          SndEscMsg( 'CPF0002': '' );
        EndIf;

        If  PxCrtDtaAra = '*NO'  And
            ChkObj( WLC_DTA: WLC_LIB: '*DTAARA' ) = *Off;

          SndDiagMsg( 'CPD0006'
                    : '0000' +
                      RtvMsg( 'CPF2105': WLC_DTA + WLC_LIB + 'DTAARA' )
                    );

          SndEscMsg( 'CPF0002': '' );
        EndIf;

        If  PxCrtDtaAra = '*YES'  And
            ChkObj( WLC_DTA: WLC_LIB: '*DTAARA' ) = *On;

          SndDiagMsg( 'CPD0006'
                    : '0000' +
                      RtvMsg( 'CPD2104': WLC_DTA + WLC_LIB + 'DTAARA' )
                    );

          SndEscMsg( 'CPF0002': '' );
        EndIf;

        If  ChkObjAut( WLC_DTA: WLC_LIB: '*DTAARA': '*CHANGE' ) = *Off;
          SndDiagMsg( 'CPD0006'
                    : '0000' +
                      RtvMsg( 'CPD0737': WLC_DTA )
                    );

          SndEscMsg( 'CPF0002': '' );
        EndIf;

        *InLr = *On;
        Return;

      /End-Free

     **-- Check object existence:
     P ChkObj          B                   Export
     D                 Pi              n
     D  PxObjNam                     10a   Const
     D  PxLibNam                     10a   Const
     D  PxObjTyp                     10a   Const
     **
     D OBJD0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a

      /Free

         RtvObjD( OBJD0100
                : %Size( OBJD0100 )
                : 'OBJD0100'
                : PxObjNam + PxLibNam
                : PxObjTyp
                : ERRC0100
                );

         If  ERRC0100.BytAvl > *Zero;
           Return  *Off;

         Else;
           Return  *On;
         EndIf;

      /End-Free

     P ChkObj          E
     **-- Check object authority:
     P ChkObjAut       B                   Export
     D                 Pi              n
     D  PxObjNam                     10a   Const
     D  PxLibNam                     10a   Const
     D  PxObjTyp                     10a   Const
     D  PxChkAut                     10a   Const

     **-- Local variables:
     D AutInd          s              1a
     D ChkAutLst       s             10a   Dim( 11 )
     **-- Local constants:
     D ADP_PRV_INVLVL  c                   1

      /Free

         ChkAutLst(1) = PxChkAut;

         ChkUsrAut( AutInd
                  : '*CURRENT'
                  : PxObjNam + PxLibNam
                  : PxObjTyp
                  : ChkAutLst
                  : 1
                  : ADP_PRV_INVLVL
                  : ERRC0100
                  );

         Select;
         When  ERRC0100.BytAvl > *Zero;
           Return  *Off;

         When  AutInd = 'Y';
           Return  *On;

         Other;
           Return  *Off;
         EndSl;

      /End-Free

     P ChkObjAut       E
     **-- Check WLC group existence:
     P ChkWlcGrp       B                   Export
     D                 Pi              n
     D  PxWlgNam                     10a   Const

     **-- API data structures:
     D WLCR0100        Ds         65535    Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  WlgNam                       10a
     D                                2a
     D  WlgPrcCap                    10i 0
     D  OfsWlgLst                    10i 0
     D  NbrWlgLstE                   10i 0
     D  LenWlgLstE                   10i 0
     **
     D WLCQ0300        Ds                  Qualified
     D  WlgNam                       10a

      /Free

        WLCQ0300.WlgNam = PxWlgNam;

        RtvWlgInf( WLCR0100
                 : %Size( WLCR0100 )
                 : 'WLCR0100'
                 : WLCQ0300
                 : 'WLCQ0300'
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero  Or
            WLCR0100.BytAvl = *Zero;
          Return  *Off;

        Else;
          Return  *On;
        EndIf;

      /End-Free

     P ChkWlcGrp       E
     **-- Retrieve message:
     P RtvMsg          B
     D                 Pi          4096a   Varying
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D RTVM0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  RtnMsgLen                    10i 0
     D  RtnMsgAvl                    10i 0
     D  RtnHlpLen                    10i 0
     D  RtnHlpAvl                    10i 0
     D  Msg                        4096a
     **
     D RPL_SUB_VAL     c                   '*YES'
     D NOT_FMT_CTL     c                   '*NO'

      /Free

        RtvMsgD( RTVM0100
               : %Size( RTVM0100 )
               : 'RTVM0100'
               : PxMsgId
               : 'QCPFMSG   *LIBL'
               : PxMsgDta
               : %Len( PxMsgDta )
               : RPL_SUB_VAL
               : NOT_FMT_CTL
               : ERRC0100
               );

        Select;
        When  ERRC0100.BytAvl > *Zero;
          Return  NULL;

        When  %Subst( RTVM0100.Msg: 1: RTVM0100.RtnMsgLen ) = PxMsgId;
          Return  %Subst( RTVM0100.Msg
                        : RTVM0100.RtnMsgLen + 1
                        : RTVM0100.RtnHlpLen
                        );

        Other;
          Return  %Subst( RTVM0100.Msg: 1: RTVM0100.RtnMsgLen );
        EndSl;

      /End-Free

     P RtvMsg          E
     **-- Send diagnostic message:
     P SndDiagMsg      B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*DIAG'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndDiagMsg      E
     **-- Send escape message:
     P SndEscMsg       B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
