     **
     **  Program . . : CBX3031
     **  Description : Add Workload Capping Subsystem - CPP
     **  Author  . . : Carsten Flensburg
     **
     **
     **
     **  Compile options:
     **    CrtRpgMod Module( CBX3031)
     **              DbgView( *LIST )
     **
     **    CrtPgm    Pgm( CBX3031)
     **              Module( CBX3031)
     **              ActGrp( *NEW )
     **
     **
     **-- Control specification:  --------------------------------------------**
     H Option( *SrcStmt )

     **-- System information:
     D PgmSts         SDs                  Qualified  NoOpt
     D  PgmNam           *Proc
     D  Status                        5a   Overlay( PgmSts: 11 )
     D  StmNbr                        8a   Overlay( PgmSts: 21 )
     D  MsgId                         7a   Overlay( PgmSts: 40 )
     D  PgmLib                       10a   Overlay( PgmSts: 81 )
     D  Msg                          80a   Overlay( PgmSts: 91 )
     D  JobId                        26a   Overlay( PgmSts: 244 )
     D  CurJob                       10a   Overlay( PgmSts: 244 )
     D  UsrPrf                       10a   Overlay( PgmSts: 254 )
     D  JobNbr                        6a   Overlay( PgmSts: 264 )
     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     D  ExcpId                        7a
     D                                1a
     D  ExcpDta                     512a

     **-- Global constants:
     D NULL            c                   ''
     D WLC_DTA         c                   'QWTWLCGRP'
     D WLC_LIB         c                   'QSYS'
     D ADP_PRV_INVLVL  c                   1
     **-- Global variables:
     D DtaOfs          s             10i 0
     D NbrElm          s             10i 0
     D NxtElm          s             10i 0
     **
     D SpcAutLst       s             10a   Dim( 8 )
     D AutFlg          s              1a

     **-- Data area data:
     D DTAA_NAME_T     Ds                  Qualified
     D  DtaAraNam                    10a
     D  DtaAraLib                    10a
     **-- Data area format:
     D WlcGrpSbs       Ds                  Qualified
     D  SbsGrp                       20a   Dim( 100 )
     D   SbsNam                      10a   Overlay( SbsGrp:  1 )
     D   WlcGrp                      10a   Overlay( SbsGrp: 11 )

     **-- Retrieve product information:
     D RtvPrdInf       Pr                  ExtPgm( 'QSZRTVPR' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  PrdInf                       27a   Const
     D  Error                      1024a         Options( *VarSize )
     **-- Check special authority
     D ChkSpcAut       Pr                  ExtPgm( 'QSYCUSRS' )
     D  AutInf                        1a
     D  UsrPrf                       10a   Const
     D  SpcAut                       10a   Const  Dim( 8 )  Options( *VarSize )
     D  NbrAut                       10i 0 Const
     D  CalLvl                       10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     **-- Retrieve data area:
     D RtvDtaAra       Pr                  ExtPgm( 'QWCRDTAA' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  DtaAra_q                     20a   Const
     D  StrPos                       10i 0 Const
     D  DtaLen                       10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     **-- Change data area:
     D ChgDtaAra       Pr                  ExtPgm( 'QXXCHGDA' )
     D  DtaAra_q                           LikeDs( DTAA_NAME_T )
     D  DtaOfs                       10i 0 Const
     D  DtaLen                       10i 0 Const
     D  DtaVal                     2000a   Const  Options( *VarSize )
     **-- Retrieve object description:
     D RtvObjD         Pr                  ExtPgm( 'QUSROBJD' )
     D  RcvVar                    32767a          Options( *VarSize )
     D  RcvVarLen                    10i 0 Const
     D  FmtNam                        8a   Const
     D  ObjNamQ                      20a   Const
     D  ObjTyp                       10a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Execute command:
     D ExcCmd          Pr                  ExtPgm( 'QCMDEXC' )
     D  CmdStr                     4096a   Const  Options( *VarSize )
     D  CmdLen                       15p 5 Const
     D  CmdIGC                        3a   Const  Options( *NoPass )
     **-- Move program messages:
     D MovPgmMsg       Pr                  ExtPgm( 'QMHMOVPM' )
     D  MsgKey                        4a   Const
     D  MsgTyps                      10a   Const  Options( *VarSize )  Dim( 4 )
     D  NbrMsgTyps                   10i 0 Const
     D  ToCalStkE                  4102a   Const  Options( *VarSize )
     D  ToCalStkCnt                  10i 0 Const
     D  Error                     32767a          Options( *VarSize )
     D  ToCalStkLen                  10i 0 Const  Options( *NoPass )
     D  ToCalStkEq                   20a   Const  Options( *NoPass )
     D  ToCalStkEdt                  10a   Const  Options( *NoPass )
     D  FrCalStkEad                    *   Const  Options( *NoPass )
     D  FrCalStkCnt                  10i 0 Const  Options( *NoPass )
     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      128a   Const
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                     32767a          Options( *VarSize )

     **-- Get system release level:
     D GetRlsLvl       Pr             6a
     **-- Check object existence:
     D ChkObj          Pr              n
     D  PxObjNam                     10a   Const
     D  PxObjLib                     10a   Const
     D  PxObjTyp                     10a   Const
     **-- Get data area character value:
     D GetDtaChr       Pr          2000a   Varying
     D  PxDtaAra                     10a   Const
     D  PxLibNam                     10a   Const
     **-- Retrieve message:
     D GetDtaLen       Pr            10i 0
     D  PxDtaAra_q                   20a   Const
     **-- Run command:
     D RunCmd          Pr            10i 0
     D  PxCmdStr                   4096a   Const  Varying
     **-- Send completion message:
     D SndCmpMsg       Pr            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying

     **-- Entry parameters:
     D SbsGrp          Ds                  Qualified
     D   NbrElm                       5i 0 Overlay( SbsGrp:  1 )
     D   WlcGrp                      10a   Overlay( SbsGrp:  3 )
     D   SbsNam                      10a   Overlay( SbsGrp: 13 )
     **
     D CBX3031         Pr
     D  PxSbsGrp                           LikeDs( SbsGrp )
     D  PxCrtDtaAra                   4a
     **
     D CBX3031         Pi
     D  PxSbsGrp                           LikeDs( SbsGrp )
     D  PxCrtDtaAra                   4a

      /Free

        If  GetRlsLvl() >= 'V7R3M0';
          SndEscMsg( 'CPF9898'
                   : 'Data area ' + WLC_DTA +
                     ' obsolete at V7R3M0 or later. Check command help text'
                   );
        EndIf;

        SpcAutLst( 1 ) = '*JOBCTL';

        ChkSpcAut( AutFlg
                 : PgmSts.UsrPrf
                 : SpcAutLst
                 : 1
                 : ADP_PRV_INVLVL
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero  Or  AutFlg = 'N';
          SndEscMsg( 'CPFB0CE': '*JOBCTL' );
        EndIf;

        If  PxCrtDtaAra = '*YES';
          ExSr  CrtDtaAra;
        EndIf;

        ExSr  RtvWlcSbs;

        ExSr  UpdDtaAra;

        *InLr = *On;
        Return;


        BegSr  RtvWlcSbs;

          WlcGrpSbs = GetDtaChr( WLC_DTA: WLC_LIB );

          DTAA_NAME_T.DtaAraNam = WLC_DTA;
          DTAA_NAME_T.DtaAraLib = WLC_LIB;

          NbrElm = GetDtaLen( DTAA_NAME_T ) / %Size( WlcGrpSbs.SbsGrp );

          If  %Lookup( PxSbsGrp.SbsNam
                     : WlcGrpSbs.SbsNam
                     : 1
                     : NbrElm
                     ) > *Zero;

            SndEscMsg( 'CPF9898'
                     : 'Subsystem ' + %Trim( PxSbsGrp.SbsNam ) +
                       ' already associated with WLC group'
                     );
          EndIf;

        EndSr;

        BegSr  UpdDtaAra;

          NxtElm = %Lookup( *Blanks: WlcGrpSbs.SbsGrp: 1: NbrElm );

          If  NxtElm = *Zero;
            SndEscMsg( 'CPF9898'
                     : 'Data area ' + WLC_DTA + ' in library ' + WLC_DTA +
                       ' cannot contain more data'
                     );
          EndIf;

          DtaOfs = (NxtElm - 1) * %Size( WlcGrpSbs.SbsGrp ) + 1;

          ChgDtaAra( DTAA_NAME_T
                   : DtaOfs
                   : %Size( WlcGrpSbs.SbsGrp )
                   : PxSbsGrp.SbsNam + PxSbsGrp.WlcGrp
                   );

          SndCmpMsg( 'Data area '   + WLC_DTA +
                     ' in library ' + WLC_LIB +
                     ' has been updated.'
                   );

        EndSr;

        BegSr  CrtDtaAra;

          If  ChkObj( WLC_DTA: WLC_LIB: '*DTAARA' ) = *Off;

            RunCmd( 'CRTDTAARA DTAARA(' + WLC_LIB + '/' + WLC_DTA + ') ' +
                    'TYPE(*CHAR) LEN(2000) AUT(*EXCLUDE)'
                  );
          EndIf;

        EndSr;

      /End-Free

     **-- Get system release level:
     P GetRlsLvl       B
     D                 Pi             6a

     **-- Product information:
     D PRDR0100        Ds                  Qualified
     D  BytPrv                       10i 0
     D  BytRtn                       10i 0
     D                               10i 0
     D  PrdId                         7a
     D  Release                       6a
     D  PrdOpt                        4a
     D  LodId                         4a
     D  LodTyp                       10a
     D  SymLodStt                    10a
     D  LodErrInd                    10a
     D  LodStt                        2a
     D  SupFlg                        1a
     D  RegTyp                        2a
     D  RegVal                       14a
     D                                2a
     D  OfsAddInf                    10i 0
     D  PriLodId                      4a
     D  MinTrgRel                     6a
     D  MinVrmBas                     6a
     D  RqmBasOpt                     1a
     D  Level                         3a

      /Free

        RtvPrdInf( PRDR0100
                 : %Size( PRDR0100 )
                 : 'PRDR0100'
                 : '*OPSYS *CUR  0000*CODE    '
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          PRDR0100.Release = *Blanks;
        EndIf;

        Return  PRDR0100.Release;

      /End-Free

     P GetRlsLvl       E
     **-- Check object existence:  -------------------------------------------**
     P ChkObj          B                   Export
     D                 Pi              n
     D  PxObjNam                     10a   Const
     D  PxObjLib                     10a   Const
     D  PxObjTyp                     10a   Const
     **
     D OBJD0100        Ds                  Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  ObjNam                       10a
     D  ObjLib                       10a
     D  ObjTyp                       10a

      /Free

         RtvObjD( OBJD0100
                : %Size( OBJD0100 )
                : 'OBJD0100'
                : PxObjNam + PxObjLib
                : PxObjTyp
                : ERRC0100
                );

         If  ERRC0100.BytAvl > *Zero;
           Return  *Off;

         Else;
           Return  *On;
         EndIf;

      /End-Free

     P ChkObj          E
     **-- Get data area character value:
     P GetDtaChr       B                   Export
     D                 Pi          2000a   Varying
     D  PxDtaAra                     10a   Const
     D  PxLibNam                     10a   Const

     **-- Global constants:
     D ALL_DTA         c                   -1
     D NULL            c                   ''
     **-- Data area data:
     D DTAA0100        Ds                  Qualified
     D  BytAvl                       10i 0
     D  BytRtn                       10i 0
     D  ValTyp                       10a
     D  LibNam                       10a
     D  ValLen                       10i 0
     D  NbrDec                       10i 0
     D  DtaVal                     2000a

      /Free

        RtvDtaAra( DTAA0100
                 : %Len( DTAA0100 )
                 : PxDtaAra + PxLibNam
                 : ALL_DTA
                 : %Size( DTAA0100.DtaVal )
                 : ERRC0100
                 );

        Select;
        When  ERRC0100.BytAvl > *Zero;
          Return  NULL;

        When  DTAA0100.ValTyp <> '*CHAR';
          Return  NULL;

        Other;
          Return  %TrimR( %Subst( DTAA0100.DtaVal: 1: DTAA0100.ValLen ));
        EndSl;

      /End-Free

     P GetDtaChr       E
     **-- Get data area length:
     P GetDtaLen       B
     D                 Pi            10i 0
     D  PxDtaAra_q                   20a   Const

     **-- Global constants:
     D ALL_DTA         c                   -1
     **-- Data area data:
     D DTAA0100        Ds                  Qualified
     D  BytAvl                       10i 0
     D  BytRtn                       10i 0
     D  ValTyp                       10a
     D  LibNam                       10a
     D  ValLen                       10i 0
     D  NbrDec                       10i 0
     D  DtaVal                     2000a

      /Free

        RtvDtaAra( DTAA0100
                 : %Len( DTAA0100 )
                 : PxDtaAra_q
                 : ALL_DTA
                 : %Size( DTAA0100.DtaVal )
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return  DTAA0100.ValLen;
        EndIf;

      /End-Free

     P GetDtaLen       E
     **-- Run command:
     P RunCmd          B
     D                 Pi            10i 0
     D  PxCmdStr                   4096a   Const  Varying

      /Free

        Monitor;
          ExcCmd( PxCmdStr: %Len( PxCmdStr ));

        On-Error;
          Return  -1;
        EndMon;

        MovPgmMsg( *Blanks: '*COMP': 1: '*PGMBDY': 1: ERRC0100 );

        Return  *Zero;

      /End-Free

     P RunCmd          E
     **-- Send completion message:
     P SndCmpMsg       B
     D                 Pi            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( 'CPF9897'
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*COMP'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return  0;

        EndIf;

      /End-Free

     P SndCmpMsg       E
     **-- Send escape message:
     P SndEscMsg       B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
