     **
     **  Program . . : CBX301
     **  Description : Display Job Workload Group - CPP
     **  Author  . . : Carsten Flensburg
     **
     **
     **
     **  Compilation specification:
     **
     **    CrtRpgMod   Module( CBX301 )
     **                DbgView( *LIST )
     **
     **    CrtPgm      Pgm( CBX301 )
     **                Module( CBX301 )
     **                ActGrp( *NEW )
     **
     **
     **-- Header specifications:  --------------------------------------------**
     H Option( *SrcStmt )

     **-- System information:
     D PgmSts         SDs                  Qualified  NoOpt
     D  PgmNam           *Proc
     D  Status                        5a   Overlay( PgmSts: 11 )
     D  StmNbr                        8a   Overlay( PgmSts: 21 )
     D  MsgId                         7a   Overlay( PgmSts: 40 )
     D  PgmLib                       10a   Overlay( PgmSts: 81 )
     D  Msg                          80a   Overlay( PgmSts: 91 )
     D  JobId                        26a   Overlay( PgmSts: 244 )
     D  CurJob                       10a   Overlay( PgmSts: 244 )
     D  UsrPrf                       10a   Overlay( PgmSts: 254 )
     D  JobNbr                        6a   Overlay( PgmSts: 264 )
     **-- API error data structure:
     D ERRC0100        Ds                  Qualified
     D  BytPrv                       10i 0 Inz( %Size( ERRC0100 ))
     D  BytAvl                       10i 0
     D  MsgId                         7a
     D                                1a
     D  MsgDta                      128a

     **-- Global constants:
     D OFS_MSGDTA      c                   16
     D NULL            c                   ''
     D ADP_PRV_INVLVL  c                   1
     **-- Global variables:
     D JobWklGrp       s             10a   Varying
     **
     D SpcAutLst       s             10a   Dim( 8 )
     D AutFlg          s              1a

     **-- Retrieve thread attribute:
     D RtvThrAtr       Pr                  ExtPgm( 'QWTRTVTA' )
     D  RcvVar                    32767a
     D  RcvVarLen                    10i 0 Const
     D  RcvInfFmt                     8a   Const
     D  JobId                        56a   Const
     D  JobIdFmt                      8a   Const
     D  NbrKeyFld                    10i 0 Const
     D  KeyFlds                      10i 0 Const  Dim( 1024 )
     D                                            Options( *VarSize )
     D  RstPfrStc                     1a   Const
     D  Error                     32767a          Options( *VarSize )
     **-- Send program message:
     D SndPgmMsg       Pr                  ExtPgm( 'QMHSNDPM' )
     D  MsgId                         7a   Const
     D  MsgFq                        20a   Const
     D  MsgDta                      512a   Const  Options( *VarSize )
     D  MsgDtaLen                    10i 0 Const
     D  MsgTyp                       10a   Const
     D  CalStkE                      10a   Const  Options( *VarSize )
     D  CalStkCtr                    10i 0 Const
     D  MsgKey                        4a
     D  Error                       512a          Options( *VarSize )
     **
     D  CalStkElen                   10i 0 Const  Options( *NoPass )
     D  CalStkEq                     20a   Const  Options( *NoPass )
     D  DspWait                      10i 0 Const  Options( *NoPass )
     **
     D  CalStkEtyp                   20a   Const  Options( *NoPass )
     D  CcsId                        10i 0 Const  Options( *NoPass )
     **-- Check special authority
     D ChkSpcAut       Pr                  ExtPgm( 'QSYCUSRS' )
     D  AutInf                        1a
     D  UsrPrf                       10a   Const
     D  SpcAut                       10a   Const  Dim( 8 )  Options( *VarSize )
     D  NbrAut                       10i 0 Const
     D  CalLvl                       10i 0 Const
     D  Error                     32767a          Options( *VarSize )

     **-- Get workload group:
     D GetJobWlg       Pr            10a
     D  PxJobNam_q                   26a   Const
     **-- Get job name qualified:
     D GetJobNam_q     Pr            28a   Varying
     D  PxJobNam_q                         LikeDs( JobNam_q )
     **-- Send completion message:
     D SndCmpMsg       Pr            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **-- Send escape message:
     D SndEscMsg       Pr            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying

     **-- Entry parameters:
     D JobNam_q        Ds
     D  JobNam                       10
     D  UsrNam                       10
     D  JobNbr                        6
     **
     D CBX301          Pr
     D  PxJobNam_q                         LikeDs( JobNam_q )
     **
     D CBX301          Pi
     D  PxJobNam_q                         LikeDs( JobNam_q )

      /Free

        If  PxJobNam_q.JobNam <> '*';
          SpcAutLst( 1 ) = '*JOBCTL';

          ChkSpcAut( AutFlg
                   : PgmSts.UsrPrf
                   : SpcAutLst
                   : 1
                   : ADP_PRV_INVLVL
                   : ERRC0100
                   );

          If  ERRC0100.BytAvl > *Zero  Or  AutFlg = 'N';
            SndEscMsg( 'CPFB0CE': 'QCPFMSG': '*JOBCTL' );
          EndIf;
        EndIf;

        JobWklGrp = GetJobWlg( PxJobNam_q );

        If  JobWklGrp > *Blanks;
          SndCmpMsg( 'Job ' + GetJobNam_q( PxJobNam_q ) +
                     ' workload capping group is '      +
                     %Trim( JobWklGrp ) + '.'
                   );

        Else;
          SndCmpMsg( 'No workload group associated with job ' +
                     GetJobNam_q( PxJobNam_q )                + '.'
                   );
        EndIf;

        *InLr = *On;
        Return;

      /End-Free

     **-- Get workload group:
     P GetJobWlg       B
     D                 Pi            10a
     D  PxJobNam_q                   26a   Const

     **-- Local variables:
     D Idx             s             10i 0
     **-- Local constants:
     D TIM_NO_RESET    c                   '0'
     D TIM_RESET       c                   '1'
     **-- Thread attribute format RTVT0100:
     D RTVT0100        Ds         32767    Qualified
     D  BytRtn                       10i 0
     D  BytAvl                       10i 0
     D  JobNam                       10a
     D  UsrNam                       10a
     D  JobNbr                        6a
     D                                2a
     D  ThrHdl                       10u 0
     D  ThrId                         8a
     D  JobSts                       10a
     D                                2a
     D  OfsKeyFld                    10i 0
     D  NbrKeyFld                    10i 0
     **
     D KeyFld          Ds                  Qualified  Based( pKeyFld )
     D  FldInfLen                    10i 0
     D  KeyNbr                       10i 0
     D  DtaTyp                        1a
     D                                3a
     D  DtaLen                       10i 0
     D  Data                        256a
     **
     D JIDF0100        Ds                  Qualified
     D  JobNam_q                     26a
     D   JobNam                      10a   Overlay( JobNam_q:  1 )
     D   UsrNam                      10a   Overlay( JobNam_q: 11 )
     D   JobNbr                       6a   Overlay( JobNam_q: 21 )
     D  IntId                        16a
     D  Rsv                           2a   Inz( *Allx'00' )
     D  ThrInd                       10i 0 Inz( -1 )
     D  ThrId                         8a   Inz( *Allx'00' )

      /Free

        JIDF0100.JobNam_q = PxJobNam_q;

        RtvThrAtr( RTVT0100
                 : %Size( RTVT0100 )
                 : 'RTVT0100'
                 : JIDF0100
                 : 'JIDF0100'
                 : 1
                 : 2301
                 : TIM_NO_RESET
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl = *Zero;
          pKeyFld = %Addr( RTVT0100 ) + RTVT0100.OfsKeyFld;

          For  Idx = 1  to  RTVT0100.NbrKeyFld;

            If  KeyFld.KeyNbr = 2301;

              Return  %Subst( KeyFld.Data: 1: KeyFld.DtaLen );
            EndIf;

            If  Idx  < RTVT0100.NbrKeyFld;
              pKeyFld += KeyFld.FldInfLen;
            EndIf;
          EndFor;
        EndIf;

        Return  *Blanks;

      /End-Free

     P GetJobWlg       E
     **-- Get job name qualified:
     P GetJobNam_q     B
     D                 Pi            28a   Varying
     D  PxJobNam_q                         LikeDs( JobNam_q )

     **-- Local variables:
     D Idx             s             10i 0

      /Free

        If  PxJobNam_q.JobNam = '*';
          Return  %Trim( PxJobNam_q.JobNam );
        Else;
          Return  %Trim( PxJobNam_q.JobNbr ) + '/' +
                  %Trim( PxJobNam_q.UsrNam ) + '/' +
                  %Trim( PxJobNam_q.JobNam );
        EndIf;

        Return  *Blanks;

      /End-Free

     P GetJobNam_q     E
     **-- Send completion message:
     P SndCmpMsg       B
     D                 Pi            10i 0
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( 'CPF9897'
                 : 'QCPFMSG   *LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*COMP'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return  0;

        EndIf;

      /End-Free

     P SndCmpMsg       E
     **-- Send escape message:
     P SndEscMsg       B
     D                 Pi            10i 0
     D  PxMsgId                       7a   Const
     D  PxMsgF                       10a   Const
     D  PxMsgDta                    512a   Const  Varying
     **
     D MsgKey          s              4a

      /Free

        SndPgmMsg( PxMsgId
                 : PxMsgF + '*LIBL'
                 : PxMsgDta
                 : %Len( PxMsgDta )
                 : '*ESCAPE'
                 : '*PGMBDY'
                 : 1
                 : MsgKey
                 : ERRC0100
                 );

        If  ERRC0100.BytAvl > *Zero;
          Return  -1;

        Else;
          Return   0;
        EndIf;

      /End-Free

     P SndEscMsg       E
