     **-- Header specifications:  --------------------------------------------**
     H BndDir( 'QC2LE' )  Option( *SrcStmt )
     **-- Global variables:  -------------------------------------------------**
     D pRFILE          s               *
     D pUsrSpc         s               *
     D rc              s             10i 0
     D StrBuf          s          10240a
     D RtnBuf          s          10240a
     **-- Global constants:  -------------------------------------------------**
     D UsrSpc          c                   'DBFLST    QTEMP'
     D No_Lock         c                   x'00000001'
     **-- Api error data structure:  -----------------------------------------**
     D ApiError        Ds
     D  AeBytPro                     10i 0 Inz( %Size( ApiError ))
     D  AeBytAvl                     10i 0 Inz
     D  AeMsgId                       7a
     D                                1a
     D  AeMsgDta                    128a
     **-- I/O feedback structure:  -------------------------------------------**
     D RIOFB           Ds                  Based( pRIOFB )
     D  pKey                           *
     D  pSysParm                       *
     D  IoRcdRrn                     10u 0
     D  IoNbrBytRw                   10i 0
     D  IoBlkCnt                      5i 0
     D  IoBlkFllBy                    1a
     D  IoBitFld                      1a
     D  IoRsv                        20a
     **-- List fields:  ------------------------------------------------------**
     D LstFld          Pr              *
     D  PxUsrSpc                     20a   Const
     D  PxFilNam                     10a   Const
     D  PxLibNam                     10a   Const
     **-- Scan alfa fields:  -------------------------------------------------**
     D ScnAlfFlds      Pr
     D  pUsrSpc                        *
     D  PxRcdBuf                  10240a   Const
     D  PxScnVal                      1a   Const
     **-- Open file:  --------------------------------------------------------**
     D Ropen           Pr              *   ExtProc( '_Ropen' )
     D  pRFile                         *   Value  Options( *String )
     D  pMode                          *   Value  Options( *String )
     **-- Close file:  -------------------------------------------------------**
     D Rclose          Pr            10i 0 ExtProc( '_Rclose' )
     D  pRFile                         *   Value
     **-- Read first record:  ------------------------------------------------**
     D Rreadf          Pr              *   ExtProc( '_Rreadf' )
     D  pRFile                         *   Value
     D  pBuffer                        *   Value
     D  BufLength                    10u 0 Value
     D  Options                      10i 0 Value
     **-- Read next record:  -------------------------------------------------**
     D Rreadn          Pr              *   ExtProc( '_Rreadn' )
     D  pRFile                         *   Value
     D  pBuffer                        *   Value
     D  BufLength                    10u 0 Value
     D  Options                      10i 0 Value
     **-- Create user space: -------------------------------------------------**
     D CrtUsrSpc       Pr                  ExtPgm( 'QUSCRTUS' )
     D  CsSpcNamQ                    20a   Const
     D  CsExtAtr                     10a   Const
     D  CsInzSiz                     10i 0 Const
     D  CsInzVal                      1a   Const
     D  CsPubAut                     10a   Const
     D  CsText                       50a   Const
     **-- Optional 1:
     D  CsReplace                    10a   Const Options( *NoPass )
     D  CsError                   32767a         Options( *NoPass: *VarSize )
     **-- Optional 2:
     D  CsDomain                     10a   Const Options( *NoPass )
     **-- Delete user space: -------------------------------------------------**
     D DltUsrSpc       Pr                  ExtPgm( 'QUSDLTUS' )
     D  DsSpcNamQ                    20a   Const
     D  DsError                   32767a         Options( *VarSize )
     **-- Program parameters:  -----------------------------------------------**
     D PxFilNam        s             10a
     D PxLibNam        s             10a
     D PxScnArg        s              1a
     **
     C     *Entry        Plist
     C                   Parm                    PxFilNam
     C                   Parm                    PxLibNam
     C                   Parm                    PxScnArg
     **
     **-- Mainline:  ---------------------------------------------------------**
     **
     C                   CallP     CrtUsrSpc( UsrSpc
     C                                      : *Blanks
     C                                      : 65535
     C                                      : x'00'
     C                                      : '*CHANGE'
     C                                      : *Blanks
     C                                      : '*YES'
     C                                      : ApiError
     C                                      )
     **
     C                   Eval      pUsrSpc     = LstFld( UsrSpc
     C                                                 : PxFilNam
     C                                                 : PxLibNam
     C                                                 )
     **
     C                   If        pUsrSpc    <> *Null
     **
     C                   Eval      pRFILE      = Ropen( %Trim( PxLibNam ) +
     C                                                  '/'               +
     C                                                  %Trim( PxFilNam )
     C                                                : 'rr, arrseq=Y'
     C                                                )
     C
     C                   If        pRFILE     <> *Null
     **
     C                   Eval      pRIOFB      = Rreadf( pRFILE
     C                                                 : %Addr( StrBuf )
     C                                                 : %Size( StrBuf )
     C                                                 : No_Lock
     C                                                 )
     **
     C                   DoW       IoNbrBytRw  > 0
     **
     C                   Eval      RtnBuf      = %SubSt( StrBuf: 1: IoNbrBytRw )
     **
     C                   CallP     ScnAlfFlds( pUsrSpc
     C                                       : RtnBuf
     C                                       : PxScnArg
     C                                       )
     **
     C                   Eval      pRIOFB      = Rreadn( pRFILE
     C                                                 : %Addr( StrBuf )
     C                                                 : %Size( StrBuf )
     C                                                 : No_Lock
     C                                                 )
     **
     C                   EndDo
     **
     C                   Eval      rc          = Rclose( pRFILE )
     C                   EndIf
     C                   EndIf
     **
     C                   CallP     DltUsrSpc( UsrSpc
     C                                      : ApiError
     C                                      )
     **
     C                   Return
     **
     **-- List fields:  ------------------------------------------------------**
     P LstFld          B                   Export
     D                 Pi              *
     D  PxUsrSpc                     20a   Const
     D  PxFilNam                     10a   Const
     D  PxLibNam                     10a   Const
     **-- List fields to user space:  ----------------------------------------**
     D LstFldSpc       Pr                  ExtPgm( 'QUSLFLD' )
     D  LfSpcNamQ                    20a   Const
     D  LfFmtNam                      8a   Const
     D  LfFilNamQual                 20a   Const
     D  LfRcdFmtNam                  10a   Const
     D  LfOvrPrc                      1a   Const
     D  LfError                   32767a         Options( *NoPass: *VarSize )
     **-- Retrieve pointer to user space: ------------------------------------**
     D RtvPtrSpc       Pr                  ExtPgm( 'QUSPTRUS' )
     D  RpSpcNamQ                    20a   Const
     D  RpPointer                      *
     D  RpError                   32767a         Options( *NoPass: *VarSize )
     **-- Return parameter:  -------------------------------------------------**
     D pUsrSpc         s               *   Inz( *Null )
     **-- List fields:  ------------------------------------------------------**
     **
     C                   CallP     LstFldSpc( PxUsrSpc
     C                                      : 'FLDL0100'
     C                                      : PxFilNam  + PxLibNam
     C                                      : '*FIRST'
     C                                      : '0'
     C                                      : ApiError
     C                                      )
     **
     C                   If        AeBytAvl    = *Zero
     **
     C                   CallP     RtvPtrSpc( PxUsrSpc
     C                                      : pUsrSpc
     C                                      )
     C                   Return    pUsrSpc
     **
     C                   Else
     C                   Return    *Null
     C                   EndIf
     **
     P LstFld          E
     **-- Scan alfa fields:  -------------------------------------------------**
     P ScnAlfFlds      B                   Export
     D                 Pi
     D  pUsrSpc                        *
     D  PxRcdBuf                  10240a   Const
     D  PxScnArg                      1a   Const
     **-- Local variables:  --------------------------------------------------**
     D FldVal          s           1024a   Varying
     **-- API format FLDL0100: List information:  ----------------------------**
     D FldLst100       Ds                  Based( pLstEnt )
     D  F1FldNam                     10a
     D  F1DtaTyp                      1a
     D  F1DtaUse                      1a
     D  F1OutBufPos                  10i 0
     D  F1InpBufPos                  10i 0
     D  F1Len                        10i 0
     D  F1Digits                     10i 0
     D  F1DecPos                     10i 0
     D  F1TxtDsc                     50a
     D  F1EdtCod                      2a
     D  F1EdtWrdLen                  10i 0
     D  F1EdtWrd                     64a
     D  F1ColHdg1                    20a
     D  F1ColHdg2                    20a
     D  F1ColHdg3                    20a
     D  F1IntFldNam                  10a
     D  F1AltFldNam                  30a
     D  F1AltFldNamLn                10i 0
     D  F1NbrChrDbcs                 10i 0
     D  F1AlwNull                     1a
     D  F1HstVarInd                   1a
     D  F1DatTimFmt                   4a
     D  F1DatTimSep                   1a
     D  F1VarFldLenIn                 1a
     D  F1TxtDscCcsId                10i 0
     D  F1DtaCcsId                   10i 0
     D  F1ColHdgCcsId                10i 0
     D  F1EdtWrdCcsId                10i 0
     D  F1Ucs2DspFldL                10i 0
     **-- API format FLDL0200: Header information:  --------------------------**
     D HdrInf          Ds                  Based( pHdrInf )
     D  FlFilNamU                    10a
     D  FlFilLibU                    10a
     D  FlFilTyp                     10a
     D  FlRcdFmtNamU                 10a
     D  FlRcdLen                     10i 0
     D  FlRcdFmtId                   13a
     D  FlRcdTxtDsc                  50a
     D                                1a
     D  FlRcdTxtCcsId                10i 0
     D  FlVarLenFldIn                 1a
     D  FlGphFldInd                   1a
     D  FlDatTimFldIn                 1a
     D  FlNulCapFldIn                 1a
     **-- User space generic header:  ---------- -----------------------------**
     D UsrSpc          Ds                  Based( pUsrSpc )
     D  UsOfsHdr                     10i 0 Overlay( UsrSpc: 117 )
     D  UsOfsLst                     10i 0 Overlay( UsrSpc: 125 )
     D  UsNumLstEnt                  10i 0 Overlay( UsrSpc: 133 )
     D  UsSizLstEnt                  10i 0 Overlay( UsrSpc: 137 )
     **-- User space pointers:  ----------------------------------------------**
     D pHdrInf         s               *   Inz( *Null )
     D pLstEnt         s               *   Inz( *Null )
     **-- Retrieve fields:  --------------------------------------------------**
     **
     C                   Eval      pHdrInf     = pUsrSpc + UsOfsHdr
     C                   Eval      pLstEnt     = pUsrSpc + UsOfsLst
     **
     C                   Do        UsNumLstEnt
     **
     C                   If        F1DtaTyp    = 'A'
     **
     C                   Eval      Fldval      = %SubSt( PxRcdBuf
     C                                                 : F1InpBufPos
     C                                                 : F1Len
     C                                                 )
     **
     C                   If        %Scan( PxScnArg: FldVal ) >  *Zero
     **
     **... Do whatever
     C                   Eval      IoRcdRrn    = IoRcdRrn
     C                   Eval      F1FldNam    = F1FldNam
     C                   Eval      FlFilNamU   = FlFilNamU
     C                   Eval      FlFilLibU   = FlFilLibU
     **
     C                   EndIf
     C                   EndIf
     **
     C                   Eval      pLstEnt     = pLstEnt + UsSizLstEnt
     C                   EndDo
     **
     C                   Return
     **
     P ScnAlfFlds      E
