     **-- Header specifications:  --------------------------------------------**
     H NoMain
     H BndDir( 'QC2LE' )  Option( *SrcStmt )
     **-- Global variables:  -------------------------------------------------**
     D RcdBuf          s           4096a
     D pRFILE          s               *
     D rc              s             10i 0
     **-- Global constants:  -------------------------------------------------**
     D Null            c                   ''
     D UsrSpc          c                   'DBFLST    QTEMP'
     **-- Api error data structure:  -----------------------------------------**
     D ApiError        Ds
     D  AeBytPro                     10i 0 Inz( %Size( ApiError ))
     D  AeBytAvl                     10i 0 Inz
     D  AeMsgId                       7a
     D                                1a
     D  AeMsgDta                    128a
     **-- Get field value:  --------------------------------------------------**
     D GetFldVal       Pr          1024a   Varying
     D  PxFilNam                     10a   Const
     D  PxFldNam                     10a   Const
     D  PxKey                       256a   Const  Varying
     **-- List fields:  ------------------------------------------------------**
     D LstFld          Pr            10i 0
     D  PxUsrSpc                     20a   Const
     D  PxFilNam                     10a   Const
     **-- Read file by key:  -------------------------------------------------**
     D Chain           Pr         10240a   Varying
     D  PxFilNam                     10a   Const
     D  PxKeyVal                    256a   Const
     **-- Retrieve field:  ---------------------------------------------------**
     D RtvFld          Pr          1024a   Varying
     D  PxUsrSpc                     20a   Const
     D  PxFldNam                     10a   Const
     **-- Edit code:  --------------------------------------------------------**
     D EditC           Pr           256a   Varying
     D  PxDecVar                       *   Value
     D  PxDecTyp                      1a   Const
     D  PxDecDig                      5u 0 Const
     D  PxDecPos                      5u 0 Const
     D  PxEdtCde                      1a   Const
     **-- Apply decimal format:  ---------------------------------------------**
     D ApyDecFmt       Pr            32a   Varying
     D  PxInpStr                     32a   Value  Varying
     D  PxDecPos                      5u 0 Const
     **-- Get field value:  --------------------------------------------------**
     P GetFldVal       B                   Export
     D                 Pi          1024a   Varying
     D  PxFilNam                     10a   Const
     D  PxFldNam                     10a   Const
     D  PxKey                       256a   Const  Varying
     **-- Local variables:  --------------------------------------------------**
     D FldVal          s           1024a   Varying
     **-- Create user space: -------------------------------------------------**
     D CrtUsrSpc       Pr                  ExtPgm( 'QUSCRTUS' )
     D  CsSpcNamQ                    20a   Const
     D  CsExtAtr                     10a   Const
     D  CsInzSiz                     10i 0 Const
     D  CsInzVal                      1a   Const
     D  CsPubAut                     10a   Const
     D  CsText                       50a   Const
     **-- Optional 1:
     D  CsReplace                    10a   Const Options( *NoPass )
     D  CsError                   32767a         Options( *NoPass: *VarSize )
     **-- Optional 2:
     D  CsDomain                     10a   Const Options( *NoPass )
     **-- Delete user space: -------------------------------------------------**
     D DltUsrSpc       Pr                  ExtPgm( 'QUSDLTUS' )
     D  DsSpcNamQ                    20a   Const
     D  DsError                   32767a         Options( *VarSize )
     **
     **-- Mainline:  ---------------------------------------------------------**
     **
     C                   CallP     CrtUsrSpc( UsrSpc
     C                                      : *Blanks
     C                                      : 65535
     C                                      : x'00'
     C                                      : '*CHANGE'
     C                                      : *Blanks
     C                                      : '*YES'
     C                                      : ApiError
     C                                      )
     **
     C                   If        LstFld( UsrSpc
     C                                   : PxFilNam
     C                                   )     > -1
     **
     C                   Eval      RcdBuf      = Chain( PxFilNam
     C                                                : PxKey
     C                                                )
     **
     C                   If        RcdBuf     <> Null
     **
     C                   Eval      FldVal      = RtvFld( UsrSpc
     C                                                 : PxFldNam
     C                                                 )
     C                   EndIf
     C                   EndIf
     **
     C                   CallP     DltUsrSpc( UsrSpc
     C                                      : ApiError
     C                                      )
     **
     C                   Return    FldVal
     **
     P GetFldVal       E
     **-- List fields:  ------------------------------------------------------**
     P LstFld          B                   Export
     D                 Pi            10i 0
     D  PxUsrSpc                     20a   Const
     D  PxFilNam                     10a   Const
     **-- List fields to user space:  ----------------------------------------**
     D LstFldSpc       Pr                  ExtPgm( 'QUSLFLD' )
     D  LfSpcNamQ                    20a   Const
     D  LfFmtNam                      8a   Const
     D  LfFilNamQual                 20a   Const
     D  LfRcdFmtNam                  10a   Const
     D  LfOvrPrc                      1a   Const
     D  LfError                   32767a         Options( *NoPass: *VarSize )
     **-- List fields:  ------------------------------------------------------**
     **
     C                   CallP     LstFldSpc( PxUsrSpc
     C                                      : 'FLDL0100'
     C                                      : PxFilNam  + '*LIBL'
     C                                      : '*FIRST'
     C                                      : '0'
     C                                      : ApiError
     C                                      )
     **
     C                   If        AeBytAvl    = *Zero
     C                   Return    0
     **
     C                   Else
     C                   Return    -1
     C                   EndIf
     **
     P LstFld          E
     **-- Read file by key:  -------------------------------------------------**
     P Chain           B                   Export
     D                 Pi         10240a   Varying
     D  PxFilNam                     10a   Const
     D  PxKeyVal                    256a   Const
     **-- I/O feedback structure:  -------------------------------------------**
     D RIOFB           Ds                  Based( pRIOFB )
     D  pKey                           *
     D  pSysParm                       *
     D  IoRcdRrn                     10u 0
     D  IoNbrBytRw                   10i 0
     D  IoBlkCnt                      5i 0
     D  IoBlkFllBy                    1a
     D  IoBitFld                      1a
     D  IoRsv                        20a
     **-- Search type constants:  --------------------------------------------**
     D Key_Eq          c                   x'0B000100'
     **-- Open file:  --------------------------------------------------------**
     D Ropen           Pr              *   ExtProc( '_Ropen' )
     D  pRFile                         *   Value  Options( *String )
     D  pMode                          *   Value  Options( *String )
     **-- Close file:  -------------------------------------------------------**
     D Rclose          Pr            10i 0 ExtProc( '_Rclose' )
     D  pRFile                         *   Value
     **-- Read by key:  ------------------------------------------------------**
     D Rreadk          Pr              *   ExtProc( '_Rreadk' )
     D  pRFile                         *   Value
     D  pBuffer                        *   Value
     D  BufLength                    10u 0 Value
     D  Options                      10i 0 Value
     D  pKey                           *   Value
     D  KeyLength                    10u 0 Value
     **
     D StrBuf          s          10240a
     D RtnBuf          s          10240a   Varying
     D KeyFld          s            256a
     **-- Chain:  ------------------------------------------------------------**
     **
     C                   Eval      pRFILE      = Ropen( PxFilNam
     C                                                : 'rr, nullcap=Y'
     C                                                )
     C
     C                   If        pRFILE     <> *Null
     **
     C                   Eval      KeyFld      = PxKeyVal
     **
     C                   Eval      pRIOFB      = Rreadk( pRFILE
     C                                                 : %Addr( StrBuf )
     C                                                 : %Size( StrBuf )
     C                                                 : Key_Eq
     C                                                 : %Addr( KeyFld )
     C                                                 : %Len( %TrimR( KeyFld ))
     C                                                 )
     **
     C                   If        IoNbrBytRw  > 0
     C                   Eval      RtnBuf      = %SubSt( StrBuf: 1: IoNbrBytRw )
     C                   EndIf
     **
     C                   Eval      rc          = Rclose( pRFILE )
     C                   EndIf
     **
     C                   Return    RtnBuf
     **
     P Chain           E
     **-- Retrieve field:  ---------------------------------------------------**
     P RtvFld          B                   Export
     D                 Pi          1024a   Varying
     D  PxUsrSpc                     20a   Const
     D  PxFldNam                     10a   Const
     **-- Local variables:  --------------------------------------------------**
     D FldVal          s           1024a
     D Idx             s             10u 0
     **-- API format FLDL0100: List information:  ----------------------------**
     D FldLst100       Ds                  Based( pLstEnt )
     D  F1FldNam                     10a
     D  F1DtaTyp                      1a
     D  F1DtaUse                      1a
     D  F1OutBufPos                  10i 0
     D  F1InpBufPos                  10i 0
     D  F1Len                        10i 0
     D  F1Digits                     10i 0
     D  F1DecPos                     10i 0
     D  F1TxtDsc                     50a
     D  F1EdtCod                      2a
     D  F1EdtWrdLen                  10i 0
     D  F1EdtWrd                     64a
     D  F1ColHdg1                    20a
     D  F1ColHdg2                    20a
     D  F1ColHdg3                    20a
     D  F1IntFldNam                  10a
     D  F1AltFldNam                  30a
     D  F1AltFldNamLn                10i 0
     D  F1NbrChrDbcs                 10i 0
     D  F1AlwNull                     1a
     D  F1HstVarInd                   1a
     D  F1DatTimFmt                   4a
     D  F1DatTimSep                   1a
     D  F1VarFldLenIn                 1a
     D  F1TxtDscCcsId                10i 0
     D  F1DtaCcsId                   10i 0
     D  F1ColHdgCcsId                10i 0
     D  F1EdtWrdCcsId                10i 0
     D  F1Ucs2DspFldL                10i 0
     **-- API format FLDL0200: Header information:  --------------------------**
     D HdrInf          Ds                  Based( pHdrInf )
     D  FlFilNamU                    10a
     D  FlFilLibU                    10a
     D  FlFilTyp                     10a
     D  FlRcdFmtNamU                 10a
     D  FlRcdLen                     10i 0
     D  FlRcdFmtId                   13a
     D  FlRcdTxtDsc                  50a
     D                                1a
     D  FlRcdTxtCcsId                10i 0
     D  FlVarLenFldIn                 1a
     D  FlGphFldInd                   1a
     D  FlDatTimFldIn                 1a
     D  FlNulCapFldIn                 1a
     **-- User space generic header:  ---------- -----------------------------**
     D UsrSpc          Ds                  Based( pUsrSpc )
     D  UsOfsHdr                     10i 0 Overlay( UsrSpc: 117 )
     D  UsOfsLst                     10i 0 Overlay( UsrSpc: 125 )
     D  UsNumLstEnt                  10i 0 Overlay( UsrSpc: 133 )
     D  UsSizLstEnt                  10i 0 Overlay( UsrSpc: 137 )
     **-- User space pointers:  ----------------------------------------------**
     D pUsrSpc         s               *   Inz( *Null )
     D pHdrInf         s               *   Inz( *Null )
     D pLstEnt         s               *   Inz( *Null )
     **-- Retrieve pointer to user space: ------------------------------------**
     D RtvPtrSpc       Pr                  ExtPgm( 'QUSPTRUS' )
     D  RpSpcNamQ                    20a   Const
     D  RpPointer                      *
     D  RpError                   32767a         Options( *NoPass: *VarSize )
     **-- Copy memory:  ------------------------------------------------------**
     D MemCpy          Pr              *   ExtProc( '_MEMMOVE' )
     D pOutMem                         *   Value
     D pInpMem                         *   Value
     D iMemSiz                       10u 0 Value
     **-- Retrieve field:  ---------------------------------------------------**
     **
     C                   CallP     RtvPtrSpc( PxUsrSpc
     C                                      : pUsrSpc
     C                                      )
     **
     C                   Eval      pHdrInf     = pUsrSpc + UsOfsHdr
     C                   Eval      pLstEnt     = pUsrSpc + UsOfsLst
     **
     C                   For       Idx = 1  To UsNumLstEnt
     **
     C                   If        F1FldNam    = PxFldNam
     **
     C                   Select
     C                   When      F1DtaTyp    = 'A'      Or
     C                             F1DtaTyp    = 'L'      Or
     C                             F1DtaTyp    = 'T'      Or
     C                             F1DtaTyp    = 'Z'
     **
     C                   CallP     MemCpy( %Addr( FldVal )
     C                                   : %Addr( RcdBuf ) +
     C                                     F1InpBufPos - 1
     C                                   : F1Len
     C                                   )
     **
     C                   When      F1DtaTyp    = 'P'      Or
     C                             F1DtaTyp    = 'Z'      Or
     C                             F1DtaTyp    = 'B'
     **
     C                   Eval      FldVal      = EditC( %Addr( RcdBuf ) +
     C                                                  F1InpBufPos - 1
     C                                                : F1DtaTyp
     C                                                : F1Digits
     C                                                : F1DecPos
     C                                                : 'P'
     C                                                )
     **
     C                   EndSl
     **
     C                   Leave
     C                   EndIf
     **
     C                   If        Idx         < UsNumLstEnt
     C                   Eval      pLstEnt     = pLstEnt + UsSizLstEnt
     C                   EndIf
     C                   EndFor
     **
     C                   Return    %TrimR( FldVal )
     **
     P RtvFld          E
     **-- Edit code:  --------------------------------------------------------**
     P EditC           B                   Export
     D                 Pi           256a   Varying
     D  PxDecVar                       *   Value
     D  PxDecTyp                      1a   Const
     D  PxDecDig                      5u 0 Const
     D  PxDecPos                      5u 0 Const
     D  PxEdtCde                      1a   Const
     **-- Local variables & constants:  --------------------------------------**
     D EdtMsk          s            256a
     D EdtMskLen       s             10i 0
     D RcvVar          s            256a
     D RcvVarLen       s             10i 0
     D ZroFilChr       s              1a
     D DecDig          s             10u 0
     **
     D T_SIGNED        c                   x'00'
     D T_FLOAT         c                   x'01'
     D T_ZONED         c                   x'02'
     D T_PACKED        c                   x'03'
     D T_UNSIGNED      c                   x'0A'
     **
     D DPA_Template_T  Ds
     D  SclTyp                        1a
     D  SclLen                        5i 0
     D   DecPos                       3i 0 Overlay( SclLen: 1 )
     D   DecLen                       3i 0 Overlay( SclLen: 2 )
     D  Rsv                          10i 0 Inz
     **-- Convert Edit Code to Mask:  ----------------------------------------**
     D CvtCdeMsk       Pr                  ExtPgm( 'QECCVTEC' )
     D  CcEdtMsk                    256a
     D  CcEdtMskLen                  10i 0
     D  CcRcvVarLen                  10i 0
     D  CcZroFilChr                   1a
     D  CcEdtCde                      1a   Const
     D  CcCcyInd                      1a   Const
     D  CcSrcVarPrc                  10i 0 Const
     D  CcSrcVarDec                  10i 0 Const
     D  CcError                   32767a          Options( *VarSize )
     **-- Edit function:  ----------------------------------------------------**
     D Edit            Pr                  ExtProc( '_LBEDIT' )
     D  RcvVar                         *   Value
     D  RcvVarLen                    10u 0 Const
     D  SrcVar                         *   Value
     D  SrcVarAtr                          Const  Like( DPA_Template_T )
     D  EdtMsk                      256a   Const
     D  EdtMskLen                    10u 0 Const
     **
     **-- Edit:  -------------------------------------------------------------**
     **
     C                   Select
     C                   When      PxDecTyp   = 'P'            Or
     C                             PxDecTyp   = 'Z'
     **
     C                   If        PxDecTyp   = 'P'
     C                   Eval      SclTyp     = T_PACKED
     C                   Else
     C                   Eval      SclTyp     = T_ZONED
     C                   EndIf
     **
     C                   Eval      DecDig     = PxDecDig
     C                   Eval      DecPos     = PxDecPos
     C                   Eval      DecLen     = PxDecDig
     **
     C                   When      PxDecTyp   = 'I'            Or
     C                             PxDecTyp   = 'U'
     **
     C                   If        PxDecTyp   = 'I'
     C                   Eval      SclTyp     = T_SIGNED
     C                   Else
     C                   Eval      SclTyp     = T_UNSIGNED
     C                   EndIf
     **
     C                   Eval      DecDig     = PxDecDig
     C                   Eval      DecPos     = *Zero
     **
     C                   If        DecDig     > 5
     C                   Eval      DecLen     = 4
     C                   Else
     C                   Eval      DecLen     = 2
     C                   EndIf
     **
     C                   When      PxDecTyp   = 'B'
     **
     C                   Eval      SclTyp     = T_SIGNED
     **
     C                   Eval      DecDig     = PxDecDig
     C                   Eval      DecPos     = *Zero
     **
     C                   If        DecDig     > 5
     C                   Eval      DecDig     = 10
     C                   Eval      DecLen     = 4
     C                   Else
     C                   Eval      DecDig     = 5
     C                   Eval      DecLen     = 2
     C                   EndIf
     C                   EndSl
     **
     C                   CallP     CvtCdeMsk( EdtMsk
     C                                      : EdtMskLen
     C                                      : RcvVarLen
     C                                      : ZroFilChr
     C                                      : PxEdtCde
     C                                      : ' '
     C                                      : DecDig
     C                                      : DecPos
     C                                      : ApiError
     C                                      )
     **
     C                   CallP(e)  Edit( %Addr( RcvVar )
     C                                 : RcvVarLen
     C                                 : PxDecVar
     C                                 : DPA_Template_T
     C                                 : EdtMsk
     C                                 : EdtMskLen
     C                                 )
     **
     C                   If        %Error
     C                   Return    Null
     **
     C                   ElseIf    PxDecTyp   = 'B'            And
     C                             PxDecPos   > *Zero
     **
     C                   Return    ApyDecFmt( %SubSt( RcvVar: 1: RcvVarLen )
     C                                      : PxDecPos
     C                                      )
     **
     C                   Else
     C                   Return    %SubSt( RcvVar: 1: RcvVarLen )
     C                   EndIf
     **
     P EditC           E
     **-- Apply decimal format:  ---------------------------------------------**
     P ApyDecFmt       B
     D                 Pi            32a   Varying
     D  PxInpStr                     32a   Value  Varying
     D  PxDecPos                      5u 0 Const
     **-- Local variables:  --------------------------------------------------**
     D ZroOfs          s              5u 0
     D DecOfs          s              5u 0
     **-- Retrieve job information:  -----------------------------------------**
     D RtvJobInf       Pr                  ExtPgm( 'QUSRJOBI' )
     D  RiRcvVar                  32767a          Options( *VarSize )
     D  RiRcvVarLen                  10i 0 Const
     D  RiFmtNam                      8a   Const
     D  RiJobNamQ                    26a   Const
     D  RiJobIntId                   16a   Const
     **-- Optional 1:
     D  RiError                   32767a          Options( *NoPass: *VarSize )
     **-- Optional 2:
     D  RiRstStc                      1a          Options( *NoPass )
     **-- Job info format JOBI0400:
     D J4RcvDta        Ds
     D  J4BytRtn                     10i 0
     D  J4BytAvl                     10i 0
     D  J4JobNam                     10a
     D  J4UsrNam                     10a
     D  J4JobNbr                      6a
     D  J4DecFmt                      1a   Overlay( J4RcvDta: 457 )
     **
     C                   CallP     RtvJobInf( J4RcvDta
     C                                      : %Size( J4RcvDta )
     C                                      : 'JOBI0400'
     C                                      : '*'
     C                                      : *Blank
     C                                      : ApiError
     C                                      )
     **
     C                   If        AeBytAvl    > *Zero
     C                   Return    PxInpStr
     C                   Else
     **
     C                   If        J4DecFmt    = 'J'
     C                   Eval      ZroOfs      = %Len( PxInpStr ) - PxDecPos
     C                   Eval      DecOfs      = ZroOfs + 1
     C                   Else
     C                   Eval      ZroOfs      = %Len( PxInpStr ) - PxDecPos + 1
     C                   Eval      DecOfs      = ZroOfs
     C                   EndIf
     **
     C                   Eval      PxInpStr    = %Xlate( ' '
     C                                                 : '0'
     C                                                 : PxInpStr
     C                                                 : ZroOfs
     C                                                 )
     C
     **
     C                   If        J4DecFmt    = ' '
     C                   Return    %Replace( '.'
     C                                     : PxInpStr
     C                                     : DecOfs
     C                                     : 0
     C                                     )
     **
     C                   Else
     C                   Return    %Replace( ','
     C                                     : PxInpStr
     C                                     : DecOfs
     C                                     : 0
     C                                     )
     C                   EndIf
     C                   EndIf
     **
     P ApyDecFmt       E
