     **
     **  Program summary
     **  ---------------
     **
     **  Hardware resource API:
     **    QRZSCHE       Search hardware       Searches the hardware resources
     **                  resource entry        for entries matching the request
     **                                        criteria(s) in the form of key
     **                                        values. Upon a succesful search
     **                                        the first or next resource name
     **                                        found is returned.
     **
     **  Sequence of events:
     **    1. The API input parameters are initialized
     **
     **    2. The search hardware resource API is called
     **
     **    3. If an error occurred calling the API or
     **       no entry is found blanks are returned to
     **       the caller
     **
     **    4. If an entry is found the resource name
     **       is retrieved and returned to the caller
     **
     **
     **  Parameters:
     **    Return-     OUTPUT     The name of electronic-customer-support
     **    value                  communications resource is returned.
     **
     **                           If no matching entry was found or an error
     **                           occurred blanks are returned to the caller.
     **
     **
     **  Compile options:
     **   CrtRpgMod  Module( CBX0061 )
     **
     **   CrtSrvPgm  Srvpgm( CBX0061 )
     **              Module( CBX0061 )
     **              Export( *ALL )
     **
     **
     **-- Control spec:  -----------------------------------------------------**
     H NoMain  Option( *SrcStmt )
     **-- Get ECS resource:  -------------------------------------------------**
     D GetEcsRsc       Pr            32a
     **-- Get ECS resource:  -------------------------------------------------**
     P GetEcsRsc       B                   Export
     D                 Pi            32a
     **-- API error data structure:  -----------------------------------------**
     D ApiError        Ds
     D  AeBytPrv                     10i 0 Inz( %Size( ApiError ))
     D  AeBytAvl                     10i 0
     **-- Search hardware resource entry: ------------------------------------**
     D SchHdwRscE      Pr                  ExtPgm( 'QRZSCHE' )
     D  ShRscNam                     32a
     D  ShRscCri                     60a   Const
     D  ShError                   32767a          Options( *VarSize )
     **-- Search hardware resource entry API parameters:  --------------------**
     D ShRscCri        Ds
     D  ScStcLen                     10i 0 Inz( %Len( ShRscCri ))
     D  ScOfsRcd                     10i 0 Inz( 37 )
     D  ScNbrRcd                     10i 0 Inz( 1 )
     D  ScHandle                     16a   Inz( *Allx'00' )
     D  ScSchRsc                     10i 0 Inz( 1 )
     D  ScSchRqs                     10i 0 Inz( 1 )
     D  ScRcdStc
     D   ScRcdLen                    10i 0 Inz( -1 )
     D                                     Overlay( ScRcdStc: 1 )
     D   ScKey                       10i 0 Inz( 25 )
     D                                     Overlay( ScRcdStc: *Next )
     D   ScDtaLen                    10i 0 Inz( 1 )
     D                                     Overlay( ScRcdStc: *Next )
     D   ScDta                       10a   Overlay( ScRcdStc: *Next )
     **
     D ShRscNam        s             32a
     **
     **-- Mainline:  ---------------------------------------------------------**
     **
     C                   CallP     SchHdwRscE( ShRscNam: ShRscCri: ApiError )
     **
     C                   If        AeBytAvl   >  *Zero
     C                   Eval      ShRscNam   =  *Blanks
     C                   EndIf
     **
     C                   Return    ShRscNam
     **
     P GetEcsRsc       E
