     **
     ** Description:
     **
     **   Create files used by IFS file api example:
     **
     **
     **-- Control spec:  -----------------------------------------------------**
     H Option( *SrcStmt )  DftActGrp( *No )  BndDir( 'QC2LE' )
     **-- Global variables:  -------------------------------------------------**
     D FILE_o          s               *
     D String          s            512a
     D rc              s             10i 0
     D Idx             s              5u 0
     **-- Global constants:  -------------------------------------------------**
     D FilNam_1        c                   '/QOpenSys/access001.log'
     D FilNam_2        c                   '/QOpenSys/access002.log'
     D LF              c                   x'25'
     **-- IFS stream file functions:  ----------------------------------------**
     D fopen           Pr              *   ExtProc( '_C_IFS_fopen' )
     D                                 *   Value  Options( *String )
     D                                 *   Value  Options( *String )
     **
     D fgets           Pr              *   ExtProc( '_C_IFS_fgets' )
     D                                 *   Value
     D                               10i 0 Value
     D                                 *   Value
     **
     D fputs           Pr            10i 0 ExtProc( '_C_IFS_fputs' )
     D                                 *   Value  Options( *String )
     D                                 *   Value
     **
     D fclose          Pr            10i 0 ExtProc( '_C_IFS_fclose' )
     D                                 *   Value
     **
     **-- Mainline:  ---------------------------------------------------------**
     **
     **-- create file, set codepage (pc):
     C                   Eval      FILE_o     =  fopen( %TrimR( FilNam_1 )
     C                                                : 'w, codepage=850'
     C                                                )
     **
     C                   Eval      rc         =  fclose( FILE_o )
     **
     C                   Eval      FILE_o     =  fopen( %TrimR( FilNam_2 )
     C                                                : 'w, codepage=850'
     C                                                )
     **
     C                   Eval      rc         =  fclose( FILE_o )
     **
     **-- open files, implicit conversion to job codepage:
     C                   Eval      FILE_o     =  fopen( %TrimR( FilNam_1 )
     C                                                : 'w'
     C                                                )
     **
     C                   If        FILE_o    <>  *Null
     **
     C                   For       Idx = 1  to 10
     C                   Eval      rc         =  fputs( 'Stream 1 line: ' +
     C                                                  %Char( Idx )      +
     C                                                  LF
     C                                                : FILE_o
     C                                                )
     C                   EndFor
     **
     C                   Eval      rc         =  fclose( FILE_o )
     C                   EndIf
     **
     **-- open files, implicit conversion to job codepage:
     C                   Eval      FILE_o     =  fopen( %TrimR( FilNam_2 )
     C                                                : 'w'
     C                                                )
     **
     C                   If        FILE_o    <>  *Null
     **
     C                   For       Idx = 1  to 10
     C                   Eval      rc         =  fputs( 'Stream 2 line: ' +
     C                                                  %Char( Idx )      +
     C                                                  LF
     C                                                : FILE_o
     C                                                )
     C                   EndFor
     **
     C                   Eval      rc         =  fclose( FILE_o )
     C                   EndIf
     **
     C                   Eval      *InLr      =  *On
     C                   Return
     **
